XSLT 包装除一个以外的任意元素

Question

我正在关注 this topic，但仍然无法解决下面描述的问题。在 <ol> 元素中，我需要根据此示例将任意元素（/节点）包装到 <li> 中：

<ol>
    text
    <p>text</p>
    <li>
        text
        <p>text</p>
    </li>
    <p>text</p>
    text
    <sub>text</sub>
</ol>

转换为：

<ol>
    <li>
        text
        <p>text</p>
    </li>
    <li>
        text
        <p>text</p>
    </li>
    <li>
        <p>text</p>
        text
        <sub>text</sub>
    </li>
</ol>

我正在使用 xslt 1.0。非常感谢任何帮助！

更新示例

<root>
    <ol>
        text
        <p>text</p>
        <li>
           text
           <p>text</p>
        </li>
        <p>text</p>
        text
        <sub>text</sub>
    </ol>
    <ol>
        text
        <p>text</p>
    </ol>
</root>

转换为：

<root>
    <ol>
        <li>
            text
            <p>text</p>
        </li>
        <li>
            text
            <p>text</p>
        </li>
        <li>
            <p>text</p>
            text
            <sub>text</sub>
        </li>
    </ol>
    <ol>
        <li>
            text
            <p>text</p>
        </li>
    </ol>
</root>

Answer 1

我会尝试将其解决为 Muenchian 分组，其中键计算 ol 元素的所有非 li 子节点的 preceding-sibling::li 元素：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:key name="group" match="ol/node()[not(self::li)]" use="count(preceding-sibling::li)"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="ol/node()[not(self::li)][generate-id() = generate-id(key('group', count(preceding-sibling::li))[1])]">
        <li>
            <xsl:copy-of select="key('group', count(preceding-sibling::li))"/>
        </li>
    </xsl:template>

    <xsl:template match="ol/node()[not(self::li)][not(generate-id() = generate-id(key('group', count(preceding-sibling::li))[1]))]"/>

</xsl:transform>

在线示例 http://xsltransform.net/pPzifpy。

XSLT 包装除一个以外的任意元素

XSLT Wrap arbitrary elements except one

xslt

xslt-1.0