为什么没有使用此代码在 Mathematica 中生成词云？

Question

data = EntityValue[CountryData[], {"Name", "Population"}];
WordCloud[data]

我得到的是这个：

WordCloud[{{"Afghanistan", Quantity[35623235, "People"]}, {"Albania", 
   Quantity[3248655, "People"]}, {"Algeria", 
   Quantity[37473690, "People"]}, {"American Samoa", 
   Quantity[54719, "People"]}, {"Andorra", 
   Quantity[85458, "People"]}, {"Angola", .....

而且没有任何图形

Answer 1

我可以使用 Heike 的 code 在 10.0 版本中获得词云，但我不得不删除有关自定义距离函数的部分，因为它令人难以置信地减慢了这个版本。

data = << "http://pastebin.com/raw/02YJ9Ntx";
range = {Min[data[[All, 2]]], Max[data[[All, 2]]]};
words = Style[#1, FontFamily -> "Times", FontWeight -> Bold, 
     FontColor -> 
      Hue[RandomReal[], RandomReal[{.5, 1}], RandomReal[{.5, 1}]], 
     FontSize -> Rescale[#2, range, {12, 70}]] & @@@ data;
wordsimg = 
  ImagePad[#, -3 - 
      BorderDimensions[#]] & /@ (Image[
       Graphics[Text[Framed[#, FrameMargins -> 2]]]] & /@ words);
wordsimgRot = 
  ImageRotate[#, RandomReal[2 Pi], Background -> White] & /@ wordsimg;
iteration2[img1_, w_] := 
 Module[{imdil, centre, diff, dimw, padding, padded1, minpos},
  dimw = ImageDimensions[w];
  padded1 = ImagePad[img1, {dimw[[1]] {1, 1}, dimw[[2]] {1, 1}}, 1];
  imdil = 
   Binarize[
    ImageCorrelate[Binarize[ColorNegate[padded1], 0.05], 
     Dilation[Binarize[ColorNegate[w], .05], 1]]];
  centre = ImageDimensions[padded1]/2;
  minpos = 
   Reverse@Nearest[Position[Reverse[ImageData[imdil]], 0], 
      Reverse[centre]][[1]];
  Sow[minpos - centre];
  diff = ImageDimensions[imdil] - dimw;
  padding[pos_] := Transpose[{#, diff - #} &@Round[pos - dimw/2]];
  ImagePad[#, (-Min[#] {1, 1}) & /@ BorderDimensions[#]] &@
   ImageMultiply[padded1, ImagePad[w, padding[minpos], 1]]]

然后就可以得到两个不同的词云，有无随机旋转，

{Fold[iteration2, wordsimgRot[[1]], Rest@wordsimgRot],
 Fold[iteration2, wordsimg[[1]], Rest@wordsimg]}

这些与您在 WordCloud[data]

版本 10.3 中获得的相比非常好

为什么没有使用此代码在 Mathematica 中生成词云？

why is a wordcloud not generated in mathematica with this code?

wolfram-mathematica

word-cloud