glDisableVertexAttribArray 在一个 Visual Studio 解决方案中有效，但在另一个解决方案中无效

Question

我遇到了一个非常奇怪的情况，glDisableVertexAttribArray 在我的一个解决方案中工作，但是当我从我的 Perforce 存储库中获取解决方案时，它没有运行并抛出一个断言。

我查看了这个 forum question，但不幸的是，它没有解决我的问题。这是我一直在处理的阴影映射，当我尝试将事物渲染到深度缓冲区然后禁用顶点属性时，它会抛出错误。

这是我的代码布局方式：

glUseProgram(shaderProgram);
glUniform1i(u_diffuseTextureLocation, 0);
glUniform1i(u_shadowMapLocation, 1);

[...]

glUseProgram(shaderProgram);

[Render some stuff to depth buffer]

glBindBuffer(GL_ARRAY_BUFFER, 0);
glBindBuffer(GL_ELEMENT_ARRAY_BUFFER, 0);
glBindVertexArray(0);
glDisableVertexAttibArray(a_normalAttribLocation); // This gives the GL_INVALID_OPERATION
                                                   // enum

这是该程序中的顶点着色器：

#version 430 core

uniform mat4 u_projection;
uniform mat4 u_view;
uniform mat4 u_model;
uniform mat4 u_lightSpaceMat;

in vec3 a_position;
in vec3 a_normal;
in vec2 a_texture;

out VS_OUT {
  vec3 v_fragPos;
  vec3 v_normal;
  vec2 v_texCoords;
  vec4 v_fragPosLightSpace;
} vs_out;

void main()
{
  gl_Position = u_projection * u_view * u_model * vec4(a_position, 1.0);
  vs_out.v_fragPos = (u_model * vec4(a_position, 1.0)).xyz;
  vs_out.v_normal = transpose(inverse(mat3(u_model))) * a_normal;
  vs_out.v_texCoords = a_texture;
  vs_out.v_fragPosLightSpace = u_lightSpaceMat * vec4(vs_out.v_fragPos, 1.0);
}

以及程序中的片元着色器：

#version 430 core

uniform sampler2D u_shadowMap;
uniform sampler2D u_diffuseTexture;

uniform vec3 u_lightPos;
uniform vec3 u_viewPos;

in VS_OUT {
  vec3 v_fragPos;
  vec3 v_normal;
  vec2 v_texCoords;
  vec4 v_fragPosLightSpace;
} fs_in;

out vec4 fragColor;

float shadowCalculation(vec4 fragPosLightSpace, vec3 normal, vec3 lightDir)
{
  // perform perspective divide
  vec3 projCoords = fragPosLightSpace.xyz / fragPosLightSpace.w;
  // transform to [0,1] range
  projCoords = projCoords * 0.5 + 0.5;
  // Get closest depth value from light's perspective (using [0,1] range
  // fragPosLight as coords)
  float closestDepth = texture(u_shadowMap, projCoords.xy).r;
  // Get depth of current fragment from lights perspective
  float currentDepth = projCoords.z;
  float bias = max(0.05 * (1.0 - dot(normal, lightDir)), 0.005);
  // Percentage closer filtering
  float shadow = 0.0;
  vec2 texelSize = 1.0 / textureSize(u_shadowMap, 0);
  for (int x = -1; x <= 1; ++x)
  {
    for (int y = -1; y <= 1; ++y)
    {
      float pcfDepth = texture(u_shadowMap, projCoords.xy + vec2(x, y) * texelSize).r;
      shadow += currentDepth - bias > pcfDepth ? 1.0 : 0.0;
    }
  }
  shadow /= 9.0;

  return shadow;
}

void main()
{
  vec3 color = texture(u_diffuseTexture, fs_in.v_texCoords).rgb;
  vec3 normal = normalize(fs_in.v_normal);
  vec3 lightColor = vec3(1.0);
  // ambient
  vec3 ambient = 0.15 * color;
  // diffuse
  vec3 lightDir = normalize(u_lightPos - fs_in.v_fragPos);
  float diff = max(dot(lightDir, normal), 0.0);
  vec3 diffuse = diff * lightColor;
  // specular
  vec3 viewDir = normalize(u_viewPos - fs_in.v_fragPos);
  float spec = 0.0;
  vec3 halfWayDir = normalize(lightDir + viewDir);
  spec = pow(max(dot(normal, halfWayDir), 0.0), 64.0);
  vec3 specular = spec * lightColor;
  // calculate shadow
  float shadow = shadowCalculation(fs_in.v_fragPosLightSpace, normal, lightDir);
  vec3 lighting = (ambient + (1.0 - shadow) * (diffuse + specular)) * color;

  fragColor = vec4(lighting, 1.0);
}

我真正感到困惑的是当我使用我的本地文件时程序运行s。但是当我从 Perforce 存储库中提取文件并尝试运行时，它会抛出异常。我检查了一下，所有必要的文件都上传到了 Perforce。似乎哪些属性实际上处于活动状态出了问题？我不确定。只是在这里挠头...

Answer 1

glBindVertexArray(0);
glDisableVertexAttibArray(a_normalAttribLocation);

glDisableVertexAttribArray 修改当前 VAO。您只是 删除了 当前的 VAO，将其设置为 0。在核心配置文件中，这意味着根本没有 VAO。在兼容性配置文件中，有一个 VAO 0，这可能就是它在其他地方工作的原因：你在另一台机器上获取兼容性配置文件。

但是，如果您使用的是 VAO，则完全不清楚为什么要禁用属性数组。 VAO 的全部要点是您不必在每一帧都调用属性数组函数。您只需绑定 VAO 即可。

glDisableVertexAttribArray 在一个 Visual Studio 解决方案中有效，但在另一个解决方案中无效

glDisableVertexAttribArray works in one Visual Studio solution, but not another

c++

opengl

glsl