Xtext 终端重叠

Question

我是 Xtext 的新手，我面临以下问题：在每个 "error id :" 行下，我可以预期每个可打印字符与 spaces/tabs 之间。我的语言是基于缩进的，所以这个 "terminal" 不能以 space 字符开头。

编辑/: 这种语言的示例代码如下所示：

package somepkg:    
    error UNKNOWN:
        Unknown error.
    error ZERO_DIVISION:
        Do not divide by zero you {0} donkey!.

我最接近这个语言规范的是：

grammar com.example.lang.ermsglang.Ermsglang with org.eclipse.xtext.xbase.Xbase hidden(WS)

import "http://www.eclipse.org/emf/2002/Ecore" as ecore
generate ermsglang "http://www.example.com/lang/ermsglang/Ermsglang"

Model:
    {Model}
    'package' name=ENAME ':'
    (BEGIN
        (expressions+=Error)+
    END)?
;

Error:
    {Error}
    'error' name=ENAME ':'
    (BEGIN
        (expressions+=Anything)+
    END)?
;

Anything:
    (ENAME|EMSG|INT)
;

//Terminals must be disjunctive
terminal ENAME:
    ('_'|'A'..'Z') ('_'|'A'..'Z')*
;

terminal EMSG:
    ('!'..'/'|':'..'@'|'['..'~')+
;

terminal SL_COMMENT: 
    '#' !('\n'|'\r')* ('\r'? '\n')?
;

// The following synthetic tokens are used for the indentation-aware blocks
terminal BEGIN: 'synthetic:BEGIN';  // increase indentation
terminal END: 'synthetic:END';      // decrease indentation

但是，这仍然允许 ENAME 或 EMSG 或 INT 终端，因此您不能将数字与字符混合使用。问题是终端必须是分离的，所以如果我像这样修改规则 "ANYTHING"：

terminal ANYTHING:
    (ENAME|EMSG|INT)+
;

或

Anything:
   (ENAME|EMSG|INT)+
;

将是 lexer/parser 的一个问题，它无法确定哪个终端是哪个。如何处理这种情况？谢谢。

//编辑：感谢 Christian 的工作示例，SL_COMMENT 仍然存在一个问题，在此示例中，第二个错误关键字以消息

突出显示

missing RULE_END at 'error'

package A : 
    error B :
        a
        #bopsa Akfkfndsfio
    error A_C_S :
        :aasdasdasd

Answer 1

以下语法适合我

grammar org.xtext.example.mydsl3.MyDsl hidden (WS, SL_COMMENT)

generate myDsl "http://www.xtext.org/example/mydsl3/MyDsl"

import "http://www.eclipse.org/emf/2002/Ecore" as ecore

Model:
    {Model}
    'package' name=ENAME ':'
    (BEGIN
        (expressions+=Error)+
    END)?
;

Error:
    {Error}
    'error' name=ENAME ':'
    (BEGIN
        (expressions+=Anything)+
    END)?
;

Anything:
    (ENAME|EMSG|INT|':')
;

//Terminals must be disjunctive
terminal ENAME:
    ('_'|'A'..'Z'|'a'..'z') ('_'|'A'..'Z'|'a'..'z')*
;
terminal INT returns ecore::EInt: ('0'..'9')+;

terminal EMSG:
    ('!'..'/'|';'..'@'|'['..'~')+
;

terminal SL_COMMENT: 
    '#' !('\n'|'\r')* ('\r'? '\n')?
;



// The following synthetic tokens are used for the indentation-aware blocks
terminal BEGIN: 'synthetic:BEGIN';  // increase indentation
terminal END: 'synthetic:END';      // decrease indentation

terminal WS         : (' '|'\t'|'\r'|'\n')+;

terminal ANY_OTHER: .;

Xtext 终端重叠

Xtext terminal overlapping

grammar

editor

xtext