Windows 批量复制多个文件夹并修改名称

Question

我正在尝试将多个文件夹复制并粘贴到一个文件夹中，这应该是一个简单的 backup/restore 过程。我可以使用以下内容创建备份副本：

for /d %%G in ("AppSettings\AppName version ?.?.?") do xcopy /e/h/k/c/i "%%~G" "%%~G_BACKUP"

我可以使用相同的变体删除它们：

do rd /s /q "%%~G"

但我不能 "restore" 因为我不能 trim 使用相同过程从名称中获取“_BACKUP”...工作文件夹名称是严格的，它必须是"AppName Vesrion #.#.#".

任何建议将不胜感激:)

Answer 1

为什么不（如果原始目录没有被删除）

for /d %%G in ("AppSettings\AppName version ?.?.?") do xcopy /e/h/k/c/i "%%~G_BACKUP" "%%~G"

或

SetLocal EnableDelayedExpansion
for /d %%G in ("AppSettings\AppName version ?.?.?_BACKUP") do (
  set "originalPath=%%G" 
  set "originalPath=!originalPath:_BACKUP=!"
  xcopy /e/h/k/c/i "%%~G" "!originalPath!"
)
EndLocal

set "originalPath=!originalPath:_BACKUP=!" 将从 originalPath

中删除任何出现的 _BACKUP

Answer 2

for /d %%G in ("AppSettings\AppName version ?.?.?_BACKUP") do (
  for /F "tokens=1 delims=_" %%g in ("%%~nxG") do (
    if exist "%%~dpG%%g" (
         rem next xcopy might ask Overwrite <full file path> (Yes/No/All)? 
      xcopy /e/h/k/c/i "%%~G" "%%~dpG%%g"
    ) else (
      move "%%~G" "%%g"
    )
  )
)

资源（必读）：

（命令参考）An A-Z Index of the Windows CMD command line
（额外的特殊性）Windows CMD Shell Command Line Syntax
(%%~nxG等特殊页面)Command Line arguments (Parameters)

Windows 批量复制多个文件夹并修改名称

Windows batch copy multiple folders with name trimming

windows

trim

wildcard

batch-file