在幻灯片放映期间永久显示调色板 - MS PowerPoint

Question

我正在使用 MS PowerPoint 制作视频课程。

不幸的是，我的工作效率大大降低了，因为在幻灯片放映期间，它需要：

4 次点击从红色笔变为蓝色荧光笔
然后，更改为绿色笔还需要点击 4 次。

这变得很麻烦，因为必须对这 3 秒的不活动突发进行乏味的视频编辑才能使课程引人入胜。

键盘快捷键（Ctrl-I 和 Ctrl-P）仅在我只为钢笔和荧光笔各使用一种颜色并且只是在两者之间切换时才有用。

我想知道是否存在任何可以在每张幻灯片底部永久显示调色板的方法。我知道这是可能的，因为我使用了 OfficeOne InkTools，它在 PowerPoint 2013 上运行良好，但它没有我想要的所有功能。我有编码经验，如果我了解需要修改哪些对象等，我愿意自己制作此功能。

提前致谢。

Answer 1

几个想法：

您可以向您的文件添加几个 VBA 例程，如下所示（根据需要调整 RGB 值）：

Sub Blue()
    With SlideShowWindows(1).View.PointerColor
        .RGB = RGB(0, 0, 255)
    End With
End Sub

Sub Red()
    With SlideShowWindows(1).View.PointerColor
        .RGB = RGB(255, 0, 0)
    End With
End Sub

根据需要添加其他颜色。

然后在幻灯片（或母版）上绘制几个矩形或其他形状，并为每个矩形指定一个动作设置运行 MACRO：蓝色（或红色或其他）。

您可以将它们设为透明，这样对于查看演示文稿的任何人来说，那里的任何形状都不会很明显。

按 Ctrl+A 将指针更改为箭头（这样您就可以单击东西），单击所需颜色的形状，然后按 Ctrl+P 将光标变回钢笔，这样您就可以以选定的颜色绘制...。

==================

另一种完全不同的方法是预先在两张不同的幻灯片上添加注释并在它们之间或在一张幻灯片上进行过渡，并根据需要对其进行动画处理。

Answer 2

如果您希望在幻灯片放映期间拥有某种动态 visible/hidden 交互式工具栏，如上所示，您可以向项目添加一个表单，其中包含所需颜色的按钮数量，并调用 Sub单击幻灯片上的对象（可见或不可见）时打开该表单。为此，请将形状添加到您的幻灯片（或母版）并将其鼠标单击操作设置为运行标准模块中的此宏：

Sub ChangePenColour()
  frmChangePenColour.Show
End Sub

然后创建一个名为 frmChangePenColour 的表单，并向其中添加 7 个按钮，分别称为 btn1 到 btn6 和 btnCancel。

然后将此代码添加到表单中：

' =======================================================
' Pen Colour Demo by YOUpresent
' Visit http://youpresent.co.uk for more PowerPoint stuff
' =======================================================
Option Explicit

Private Sub btn1_Click()
  ChangePointerColor btn1.BackColor
  Unload Me
End Sub

Private Sub btn2_Click()
  ChangePointerColor btn2.BackColor
  Unload Me
End Sub

Private Sub btn3_Click()
  ChangePointerColor btn3.BackColor
  Unload Me
End Sub

Private Sub btn4_Click()
  ChangePointerColor btn4.BackColor
  Unload Me
End Sub

Private Sub btn5_Click()
  ChangePointerColor btn5.BackColor
  Unload Me
End Sub

Private Sub btn6_Click()
  ChangePointerColor btn6.BackColor
  Unload Me
End Sub

Private Sub UserForm_Activate()
  CentreForm Me
End Sub

Private Sub UserForm_Initialize()
  With SlideShowWindows(1).View.Slide.Design.SlideMaster.Theme
    btn1.BackColor = .ThemeColorScheme(msoThemeAccent1).RGB
    btn2.BackColor = .ThemeColorScheme(msoThemeAccent2).RGB
    btn3.BackColor = .ThemeColorScheme(msoThemeAccent3).RGB
    btn4.BackColor = .ThemeColorScheme(msoThemeAccent4).RGB
    btn5.BackColor = .ThemeColorScheme(msoThemeAccent5).RGB
    btn6.BackColor = .ThemeColorScheme(msoThemeAccent6).RGB
  End With
End Sub

Sub ChangePointerColor(lRGB As Long)
  With SlideShowWindows(1).View
    .PointerColor = lRGB
    .PointerType = ppSlideShowPointerPen
  End With
End Sub

Private Sub btnCancel_Click()
  Unload Me
End Sub

' Centres a form wrt the PowerPoint application window
Public Sub CentreForm(thisForm As Object)
  On Error Resume Next
  ' Position in the centre of the PowerPoint window
  With thisForm
    .Left = Application.Left + ((Application.Width / 2) - (.Width / 2))
    .Top = Application.Top + ((Application.Height / 2) - (.Height / 2))
  End With
  If Err Then Debug.Print Err & Err.Description & " in CentreForm"
  On Error GoTo 0
End Sub

现在当您运行放映幻灯片时，您可以单击您选择的活动形状以打开颜色选择器并开始使用该颜色进行注释。

然后，如果您希望该工具栏在幻灯片放映开始时自动出现，并且在单击颜色时不消失，您可以添加以下子项：

Sub OnSlideShowPageChange(ByVal Wn As SlideShowWindow)
  frmChangePenColour.Show
End Sub

并将表单的 ShowModal 属性更改为 false。

您可能想要调整 UI 逻辑，但这应该足以让您继续前进。

在幻灯片放映期间永久显示调色板 - MS PowerPoint

Permanently display color palette during slideshow - MS PowerPoint

powerpoint