OpenglGL 上的级联阴影贴图纹理访问错误

Question

我正在尝试实现级联阴影贴图，但当我想访问平截头体每个分区的相应深度纹理时出现错误。

更具体地说，当我想要 select 正确的阴影纹理时，我的问题出现了，如果我尝试下面的代码，我有一个像 this 图片中的人工制品，你正在看立方体的阴影，工件是截锥体边界之间的小 dot/square（红色代表近切，绿色代表远切）

uniform sampler2D   shadowMaps[10];         //GL_TEXTURE5

uniform float       cameraFrustumZPartitionning[10];
uniform int         cameraFrustumSize;

int getCSMlevel(float Z){
    for(int iZ = 0 ; iZ < cameraFrustumSize; ++iZ)
        if(Z < cameraFrustumZPartitionning[iZ])
            return iZ;
    return -1;
}


float ShadowCalculation(vec4 fragPosLightSpace[3], int shadowMapId, float NdotD) //WIP
{
    int csmLevel = getCSMlevel(ClipSpacePosZ);

    vec4 fragPosLS = fragPosLightSpace[csmLevel];
    vec3 projCoords = fragPosLS.xyz / fragPosLS.w;

    // Transform to [0,1] range
    projCoords = projCoords * 0.5 + 0.5;

    float closestDepth = 0.0;


    if(csmLevel == -1)
        return 0.0;
    closestDepth = texture(shadowMaps[csmLevel], projCoords.xy).r;

    return 1.0 - ((projCoords.z  > closestDepth)?1.0:0.0);
}

如果我尝试此代码，一切都很好。

uniform sampler2D   shadowMaps[10];         //GL_TEXTURE5

uniform float       cameraFrustumZPartitionning[10];
uniform int         cameraFrustumSize;

int getCSMlevel(float Z){
    for(int iZ = 0 ; iZ < cameraFrustumSize; ++iZ)
        if(Z < cameraFrustumZPartitionning[iZ])
            return iZ;
    return -1;
}


float ShadowCalculation(vec4 fragPosLightSpace[3], int shadowMapId, float NdotD) //WIP
{
    int csmLevel = getCSMlevel(ClipSpacePosZ);

    vec4 fragPosLS = fragPosLightSpace[csmLevel];
    vec3 projCoords = fragPosLS.xyz / fragPosLS.w;

    // Transform to [0,1] range
    projCoords = projCoords * 0.5 + 0.5;

    float closestDepth = 0.0;



    if(csmLevel == 0)
        closestDepth = texture(shadowMaps[0], projCoords.xy).r;
    else if(csmLevel == 1)
        closestDepth = texture(shadowMaps[1], projCoords.xy).r;
    else if(csmLevel == 2)
        closestDepth = texture(shadowMaps[2], projCoords.xy).r;
    else
        return 0.0;

    return 1.0 - ((projCoords.z  > closestDepth)?1.0:0.0);
}

在 GLSL 中，我们能够制作 sampler2D 数组并通过使用变量访问数组来获得正确的数组，或者我在这里犯了一个巨大的错误？

Answer 1

来自 GLSL 4.50 规范：

When aggregated into arrays within a shader, samplers can only be indexed with a dynamically uniform integral expression, otherwise results are undefined.

这意味着所有片段着色器调用都应评估为使用相同的索引。你的第一个代码显然不满足。在第二个版本中，执行是明确发散的，因此对于每个代码路径，索引是动态统一的。

编辑： 由于您的阴影贴图可能大小相同，因此您可以改用 array textures。（数组纹理不是采样器数组。）

OpenglGL 上的级联阴影贴图纹理访问错误

Cascaded shadow map texture access bug on OpenglGL

opengl

glsl

shadow-mapping