XSLT

Question

这是我的 XML 使用 XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<s:Envelope xmlns:s="http://schemas.xmlsoap.org/soap/envelope/">
    <s:Body>
        <RequestResponse xmlns="http://tempuri.org/">
            <RequestResult>
                <Message>Request inserted successfully.</Message>
                <Response>true</Response>
            </RequestResult>
        </RequestResponse>
    </s:Body>
</s:Envelope>

并且我想在RequestResult节点中添加两个命名空间（我想要的结果）：

<?xml version="1.0" encoding="UTF-8"?>
<s:Envelope xmlns:s="http://schemas.xmlsoap.org/soap/envelope/">
    <s:Body>
        <RequestResponse xmlns="http://tempuri.org/">
            <RequestResult xmlns:a="http://schemas.datacontract.org/2004/07/MockupTesting" xmlns:i="http://www.w3.org/2001/XMLSchema-instance">
                <a:Message>Request inserted successfully.</a:Message>
                <a:Response>true</a:Response>
            </RequestResult>
        </RequestResponse>
    </s:Body>
</s:Envelope>

我使用这个 XSLT：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:i="http://www.w3.org/2001/XMLSchema-instance">

    <xsl:output omit-xml-declaration="yes" indent="yes" />

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/">
        <s:Envelope xmlns:s="http://schemas.xmlsoap.org/soap/envelope/">
            <s:Body>
                <xsl:apply-templates />
            </s:Body>
        </s:Envelope>
    </xsl:template>

    <xsl:template match="RequestResult |RequestResult //*">
        <xsl:element name="a:{name()}"
            namespace="http://schemas.datacontract.org/2004/07/MockupTesting">
            <xsl:copy-of select="namespace::*" />
            <xsl:apply-templates select="node()|@*" />
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

但是我需要添加到 SolicitarPeticionResult 节点（已经包含一个命名空间）：

xmlns:i="http://www.w3.org/2001/XMLSchema-instance"

Answer 1

在以下情况下向元素 X 添加命名空间：(i) X 的名称静态未知，并且 (ii) 命名空间未实际用于 X 的名称或其任何属性的名称:

(a) 在 XSLT 2.0 中，使用 xsl:namespace 指令

(b) 在 XSLT 1.0 中，使用 xsl:copy-of 从已经具有此命名空间的元素复制命名空间。例如，创建一个单独的文档dummy.xml

<i:dummy xmlns:i="http://www.w3.org/2001/XMLSchema-instance"/>

然后

<xsl:copy-of select="document('dummy.xml')/*/namespace::i"/>

Answer 2

你为什么不简单地做：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xpath-default-namespace="http://tempuri.org/">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="RequestResult">
    <RequestResult xmlns="http://tempuri.org/" xmlns:a="http://schemas.datacontract.org/2004/07/MockupTesting" xmlns:i="http://www.w3.org/2001/XMLSchema-instance">
        <xsl:apply-templates/>
    </RequestResult>
</xsl:template>

<xsl:template match="RequestResult/*">
    <xsl:element name="a:{name()}" namespace="http://schemas.datacontract.org/2004/07/MockupTesting">
        <xsl:apply-templates/>
    </xsl:element>
</xsl:template>

</xsl:stylesheet>

XSLT - 在一个节点中添加两个名称空间

XSLT - Add two namespaces in one node

xml

xml-namespaces