当第一个条件变为 FALSE 时，如何在 excel 中嵌套更多 IF 条件？

Question

excel不接受公式

=IF(AND(Sheet1!BZ2<>"",Sheet1!CB2<>"",Sheet1!CD2<>"",Sheet1!CF2<>"",Sheet1!CH2<>"",Sheet1!CA2="",Sheet1!BC2="B"), IF(Sheet1!CA2="","",TODAY()-1),
    IF(
        IF(AND(Sheet1!BZ2<>"",Sheet1!CA2="",Sheet1!BC2="A"),IF(Sheet1!CA2="","",TODAY()-1),
            IF(
                IF(AND(OR(Sheet1!DB2="Completed - Knowledge Transfer"),AND(Sheet1!BC2<>"")),IF(Sheet1!CA2="","",TODAY()-1),
                IF(Sheet1!CA2="","",Sheet1!CA2)
                  )
       )
  )

我遵循 IF 的以下语法。

=IF (logical_test, [value_if_true], [value_if_false])

我试图在语句得到 FALSE 时嵌套其他条件请帮忙。

谁能找出我在这个地方做的语法错误

Answer 1

语法是嵌套语法（假设 a1 = 12 和 b2=15:)

=IF(A1<13,IF(B1>13,"B1","Not Found"),"Not Found")

Answer 2

您过度使用了 IF() 公式。我试图简化你的公式，检查一下：

=IF(AND(Sheet1!BZ2<>"",Sheet1!CB2<>"",Sheet1!CD2<>"",Sheet1!CF2<>"",Sheet1!CH2<>"",Sheet1!CA2="",Sheet1!BC2="B"),IF(Sheet1!CA2="","",TODAY()-1),IF(AND(Sheet1!BZ2<>"",Sheet1!CA2="",Sheet1!BC2="A"),IF(Sheet1!CA2="","",TODAY()-1),IF(OR(Sheet1!DB2="Completed - Knowledge Transfer",Sheet1!BC2<>""),IF(Sheet1!CA2="","",TODAY()-1),IF(Sheet1!CA2="","",TODAY()-1))))

上面公式的嵌套视图：

=IF(AND(Sheet1!BZ2<>"",Sheet1!CB2<>"",Sheet1!CD2<>"",Sheet1!CF2<>"",Sheet1!CH2<>"",Sheet1!CA2="",Sheet1!BC2="B"), 
    IF(Sheet1!CA2="","",TODAY()-1),IF(AND(Sheet1!BZ2<>"",Sheet1!CA2="",Sheet1!BC2="A"),
        IF(Sheet1!CA2="","",TODAY()-1),
        IF(OR(Sheet1!DB2="Completed - Knowledge Transfer",Sheet1!BC2<>""),    
              IF(Sheet1!CA2="","",TODAY()-1),
              IF(Sheet1!CA2="","",TODAY()-1)
        )
     )
  )

Answer 3

If 语句没有正确嵌套，而且您使用了一些 AND Or 语句，这些语句再次使用不当。

简化你的公式我们得到这个

=IF(a,b,IF(IF(c,d,IF(IF(e,f,g)))

其中，

 a = AND(Sheet1!BZ2<>"",Sheet1!CB2<>"",Sheet1!CD2<>"",Sheet1!CF2<>"",Sheet1!CH2<>"",Sheet1!CA2="",Sheet1!BC2="B") 

 b = IF(Sheet1!CA2="","",TODAY()-1)

 c = AND(Sheet1!BZ2<>"",Sheet1!CA2="",Sheet1!BC2="A")

 d = IF(Sheet1!CA2="","",TODAY()-1)

 e = AND(OR(Sheet1!DB2="Completed - Knowledge Transfer"),AND(Sheet1!BC2<>""))This does not make sense

 f = IF(Sheet1!CA2="","",TODAY()-1)

 g = IF(Sheet1!CA2="","",Sheet1!CA2)

正确的嵌套 IF 的形式为

=IF(a,b,IF(c,d,IF(e,f,g)))

Answer 4

你的公式也可以写成：

=IF(Sheet1!CA2="","",
IF(OR(
AND(Sheet1!BZ2<>"",Sheet1!CB2<>"",Sheet1!CD2<>"",Sheet1!CF2<>"",Sheet1!CH2<>"",Sheet1!BC2="B"),
AND(Sheet1!BZ2<>"",Sheet1!BC2="A"),
AND(Sheet1!DB2="Completed - Knowledge Transfer",Sheet1!BC2<>"")),
TODAY()-1,Sheet1!CA2))

当第一个条件变为 FALSE 时，如何在 excel 中嵌套更多 IF 条件？

How to nest more IF conditions in excel when first condition becomes FALSE?

excel

excel-2007

excel-formula

excel-2010