Ecto + Elixir：如何查询哈希映射字段？

Question

我有一个模型：

defmodule VideoChat.User do
  use VideoChat.Web, :model

  schema "users" do
    field :device_identifier, :string
    field :matches, :map

    timestamps()
  end

  ...
end

我如何查找所有在 matches 哈希中具有 "cool" 键的用户？

User |> where([u], u.matches["cool"] != nil) |> limit(1) |> VideoChat.Repo.one

Answer 1

:map 字段由 Ecto 在 PostgreSQL 中存储为 JSONB 字段。 Ecto 不提供任何功能来对此类字段进行地图特定操作，但可以使用 fragment 和自定义 SQL.

来完成

SQL 查询 foo.bar ? 'baz' 将检查 foo 的列 bar 是否包含键 "baz" 中的值。这可以用 fragment 表示，如下所示：

fragment("? \? ?", foo.bar, "baz")

所以你的代码应该修改为：

User |> where([u], fragment("? \? ?", u.matches, "cool")) |> limit(1) |> VideoChat.Repo.one

在一个全新的 Map 模型中，密钥 map 类型为 :map:

iex(1)> Repo.insert! %MyApp.Map{map: %{}}
iex(2)> Repo.insert! %MyApp.Map{map: %{foo: 1}}
iex(3)> Repo.insert! %MyApp.Map{map: %{foo: 2}}
iex(4)> Repo.insert! %MyApp.Map{map: %{bar: 1}}
iex(5)> Repo.all MyApp.Map |> where([m], fragment("? \? ?", m.map, "foo"))
[debug] QUERY OK source="maps" db=1.8ms decode=5.3ms
SELECT m0."id", m0."map", m0."inserted_at", m0."updated_at" FROM "maps" AS m0 WHERE (m0."map" ? 'foo') []
[%MyApp.Map{__meta__: #Ecto.Schema.Metadata<:loaded, "maps">, id: 2,
  inserted_at: #Ecto.DateTime<2016-12-07 10:19:53>, map: %{"foo" => 1},
  updated_at: #Ecto.DateTime<2016-12-07 10:19:53>},
 %MyApp.Map{__meta__: #Ecto.Schema.Metadata<:loaded, "maps">, id: 3,
  inserted_at: #Ecto.DateTime<2016-12-07 10:19:55>, map: %{"foo" => 2},
  updated_at: #Ecto.DateTime<2016-12-07 10:19:55>}]
iex(6)> Repo.all MyApp.Map |> where([m], fragment("? \? ?", m.map, "bar"))
[debug] QUERY OK source="maps" db=2.9ms queue=0.2ms
SELECT m0."id", m0."map", m0."inserted_at", m0."updated_at" FROM "maps" AS m0 WHERE (m0."map" ? 'bar') []
[%MyApp.Map{__meta__: #Ecto.Schema.Metadata<:loaded, "maps">, id: 4,
  inserted_at: #Ecto.DateTime<2016-12-07 10:19:59>, map: %{"bar" => 1},
  updated_at: #Ecto.DateTime<2016-12-07 10:19:59>}]
iex(7)> Repo.all MyApp.Map |> where([m], fragment("? \? ?", m.map, "baz"))
[debug] QUERY OK source="maps" db=2.2ms queue=0.1ms
SELECT m0."id", m0."map", m0."inserted_at", m0."updated_at" FROM "maps" AS m0 WHERE (m0."map" ? 'baz') []
[]

Ecto + Elixir：如何查询哈希映射字段？

Ecto + Elixir: How do I query a hashmap field?

elixir

ecto

phoenix-framework