如何为 FsCheck 创建具有固定项目列表的生成器

Question

我最初尝试创建一个固定前 5 个元素的生成器（并且在使用 Prop.forAll 的任何测试中，前五个总是运行），但没有这样做。

现在我试图通过一个范围内的随机数据生成器和一个非随机数据生成器（即固定序列）来简化这一过程。它类似于 Gen.constant，只是它不是一个值，而是一系列值。

我有这个（简化的可重现示例，适用于 NUnit 和 xUnit）：

[<Property(Verbose = true, MaxTest=5)>]
static member MultiplyIdentityCornerCases () =
    Gen.elements [0L; -1L; 1L; Int64.MinValue; Int64.MaxValue]
    |> Arb.fromGen 
    |> Prop.forAll <| fun x -> x = x * 1L

输出是（不知道 null 来自哪里）：

0:
<null>
9223372036854775807L
1:
<null>
-9223372036854775807L
2:
<null>
-9223372036854775807L
3:
<null>
1L
4:
<null>
-9223372036854775807L
Ok, passed 5 tests.

我希望输出包含序列中的所有五个测试，最好但不一定按顺序包含。我知道我可以使用测试数据提供程序对 NUnit（或任何单元测试系统）执行此操作，但我想知道我是否可以使用 FsCheck 执行此操作（或者我是否应该这样做，也许这是个坏主意）。

我认为使用FsCheck 是有用的，至于有多个函数参数的情况，我希望它能够详尽地测试我给它的corner case 参数的所有组合。希望使用 FsCheck 比使用测试数据提供程序更容易。

Answer 1

我不知道那是可能的，但你可以这样做：

open System
open FsCheck
open FsCheck.Xunit

[<Property>]
let MultiplyIdentityCornerCases () =
    Gen.oneof [
        Gen.elements [Int64.MinValue; -1L; 0L; 1L; Int64.MaxValue]
        Arb.generate ]
    |> Arb.fromGen
    |> Prop.forAll <| fun x -> x = x * 1L

两个生成器被传递给 Gen.oneof，因此每个生成器将生成大约一半的值。

Gen.elements 应该从提供的序列中的所有值中统一选择，因此它将使用例如0L 20% 的时间，但只有当 Gen.oneof 使用 Gen.elements.

时的那一半

换句话说，每个 'special' 值都会在 50% * 20% = 10% 的时间内生成。

默认情况下，一个属性运行s 100个测试用例，所以平均来说，它应该生成10个0L值，10个Int64.MinValue值，等等.这通常就足够了。

如果不是，您可以随时执行以下操作：

open System
open Xunit
open FsCheck
open FsCheck.Xunit
open Swensen.Unquote

[<Theory>]
[<InlineData(Int64.MinValue)>]
[<InlineData(-1L)>]
[<InlineData( 0L)>]
[<InlineData( 1L)>]
[<InlineData(Int64.MaxValue)>]
let MultiplyIdentityCornerCases x = x =! x * 1L

[<Property>]
let MultiplyIdentityCornerCasesProperty x =
    MultiplyIdentityCornerCases x

在这里，您使用 xUnit.net 的 [<Theory>] 功能定义了一个参数化测试，并为其提供了您所关注的五个极端情况。当您运行测试时，测试运行ner 将运行那五个测试用例。

此外，它将运行 MultiplyIdentityCornerCasesProperty 因为它用 [<Property>] 注释，并且该函数只是调用另一个函数。

如何为 FsCheck 创建具有固定项目列表的生成器

How to create a generator with a fixed list of items for FsCheck

random

f#

fscheck