FLAT 操作数对 SEGMENT 指令的影响？

Question

MASM 提供了一个 SEGMENT 指令。该指令有几个参数。 use 参数可以取值 FLAT。我不清楚这个值的作用。

Microsoft docs 将其指定为可接受的值，但不尝试描述它：

use
USE16, USE32, FLAT

在线提供的 The Art of Assembly Language Programming 一书提到了它，但称它超出了范围，建议阅读 MASM 程序员指南：

The use32 and flat operands tell MASM to generate code for a 32 bit segment. Since this text does not deal with protected mode programming we will not consider these options. See the MASM Programmer's Guide for more details.

在 Microsoft 的 MASM 6.1 程序员指南中，在描述 SEGMENT 指令的部分中，提到了 FLAT 值，但从未描述其作用：

The size attribute can be USE16, USE32, or FLAT.

FLAT 操作数对 SEGMENT 指令有什么影响？

Answer 1

对于大多数用途，在段指令中使用的 FLAT 关键字与 USE32 具有相同的含义。 USE32 和 FLAT 关键字都表明该段可以大于 64K，并且该段中汇编的任何指令都应使用 32 位编码而不是 16 位编码。不同之处在于汇编程序对 CS 寄存器的假设。通常，SEGMENT 指令会导致隐式 ASSUME CS:xxx 指令，其中 xxx 是段的名称，但对于 FLAT，它会导致隐式 ASSUME CS:FLAT.

ASSUME 指令告诉汇编程序将哪些段加载到哪些段寄存器中，以便它可以在需要时自动使用正确的段覆盖。在大多数 32 位操作系统使用的平面内存模型中，只有一个 4 GB 的段。告诉汇编程序它可以假定段寄存器是 FLAT 告诉汇编程序可以通过该段寄存器访问程序中定义的所有段。例如 ASSUME DS:FLAT 表示所有段都可以通过 DS 寄存器访问。另一方面 ASSUME DS:_DATA 表示 DS 寄存器只能用于访问 _DATA 段而不能访问任何其他段。

您可以通过汇编以下代码来查看此行为：

_DATA   SEGMENT PUBLIC USE32
var DD  ?
_DATA   ENDS

_TEXT   SEGMENT PUBLIC PARA 'CODE' FLAT

    mov eax, [zero]
    mov [var],eax 

    ASSUME  DS:FLAT

    mov eax, [zero]
    mov [var],eax 

    ASSUME  CS:_TEXT  
    ASSUME  DS:_DATA

    mov eax, [zero]
    mov [var],eax 

zero    DD  0

_TEXT   ENDS

    END

如果反汇编生成的目标文件，您会在前两条指令中看到：

  00000000: 2E A1 00 00 00 00  mov         eax,dword ptr cs:[zero]
  00000006: 2E A3 00 00 00 00  mov         dword ptr cs:[var],eax

对于这两条指令，汇编程序必须使用 CS 段覆盖 (2E) 才能访问 zero 和 var。这是因为虽然汇编程序知道 CS 可用于访问所有段，包括 _TEXT 和 _DATA，但它不知道任何其他段寄存器可用于访问这些段。

这是它为接下来的两条指令生成的代码，在 ASSUME DS:_FLAT 指令之后：

  0000000C: A1 00 00 00 00     mov         eax,dword ptr [zero]
  00000011: A3 00 00 00 00     mov         dword ptr [var],eax

现在汇编程序知道 CS 和 DS 都可以用来访问所有的段。由于使用 DS 访问 zero 和 var 不需要段覆盖，它使用 DS 而不是 CS 导致更短的指令。

最后两条指令，在 ASSUME DS:_DATA 和 ASSUME CS:_TEXT 指令之后，显示了如果根本不使用 FLAT 关键字，汇编程序将生成的代码：

  00000016: 2E A1 00 00 00 00  mov         eax,dword ptr cs:[zero]
  0000001C: A3 00 00 00 00     mov         dword ptr [var],eax

在这种情况下，汇编程序假定 CS 只能用于访问 _TEXT，而 DS 只能用于访问 _DATA。它必须使用 CS 覆盖来访问 zero，而它只能通过 DS 访问 var，这不需要段覆盖。

请注意，如果您在上面示例代码的 SEGMENT 指令中将 FLAT 更改为 USE32，那么第一条指令将使用 CS 覆盖结束，但第二条指令会产生以下错误：

error A2074:cannot access label through segment registers

那是因为虽然汇编器知道它可以通过 CS 寄存器访问 _TEXT，但它不知道它可以用来访问 _DATA 的任何段寄存器。

如果您在代码开头使用 .MODEL FLAT 指令，您就不必担心这些。然后 USE32 和 FLAT 在段指令中具有完全相同的效果，因为每个段寄存器都被假定为 FLAT。

FLAT 操作数对 SEGMENT 指令的影响？

Effects of the FLAT operand to the SEGMENT directive?

x86

assembly

masm