如何在 kdb 中加入 table 中的字符串？

Question

我想在 kdb 中加入字符串，但效果不佳。这是数据：

tab:([]service:`CS`CS.US`CS.US_ABC;y:1 2 3)


`CS 1
`CS.US  2
`CS.US_ABC  3

我想根据给定的参数添加 :0 和 :primary。 0 正在工作

update service:`$(((string[service],'(":"))),'("C"$string 0)) from tab

如果我希望数据变成

`CS:primary 1
`CS.US:primary  2
`CS.US_ABC:primary  3

主要是字符串或符号，我该如何加入？

我正在参数化 0 和主节点。

目前0的工作方式如下

update service:`$(((string[service],'(":"))),'( "0")) from tab

但 "primary" 不工作

update service:`$(((string[service],'(":"))),'( "primary")) from tab

Answer 1

  q)update service:`$(((string[service],'(":"))),'(count[i]#enlist "primary")) 
  from tab
  service           y
  -------------------
  CS:primary        1
  CS.US:primary     2
  CS.US_ABC:primary 3

Answer 2

如果您希望 primary 成为参数而不是固定字符串，则可以使用以下方法（本例中 primary 为 "no"）：

q)update {`$string[y],\:":",x}[primary;]service from tab
service      y
--------------
CS:no        1
CS.US:no     2
CS.US_ABC:no 3

如果 primary 是固定字符串，那么您可以将其放在 lambda 中代替 "x"，并将 "y" 替换为 "x"，得到以下结果：

q)update {`$string[x],\:":","primary"}service from tab
service           y
-------------------
CS:primary        1
CS.US:primary     2
CS.US_ABC:primary 3

Answer 3

你的查询给你一个长度错误：

q)tab:([]service:`CS`CS.US`CS.US_ABC;y:1 2 3)
q)update service:`$(((string[service],'(":"))),'( "primary")) from tab
'length
  [0]  update service:`$(((string[service],'(":"))),'( "primary")) from tab
                                                    ^

发生这种情况是因为 ,'（连接每个）期望两边的向量长度相等，但在左侧得到一个 table 列大小 (3) 向量和一个长度为 7 的字符向量在右边。注意传递 3 个字符时会发生什么：

q)update service:`$(((string[service],'(":"))),'( "pri")) from tab
service     y
-------------
CS:p        1
CS.US:r     2
CS.US_ABC:i 3

每一行都有不同的后缀。你想要的是使用 ,\: （连接每个左边）：

q)update service:`$(((string[service],'(":"))),\:( "primary")) from tab
service           y
-------------------
CS:primary        1
CS.US:primary     2
CS.US_ABC:primary 3

为什么它对“0”有效？它起作用是因为“0”不是向量而是字符标量

q)type "0"
-10h
q)type "primary"
10h

右边有一个标量，,' 与 .\::

的作用相同

q)"ab",'"0"
"a0"
"b0"
q)"ab",\:"0"
"a0"
"b0"

最后，如果您先将“:”添加到后缀，然后将结果附加到每个服务，您的查询将运行更快：

q)update service:`$(string[service],\:":","primary") from tab
service           y
-------------------
CS:primary        1
CS.US:primary     2
CS.US_ABC:primary 3

如何在 kdb 中加入 table 中的字符串？

How to join strings in a table in kdb?

kdb