存储过程 - 消息 102，级别 15，状态 1，第 3 行 '' 附近的语法不正确

Question

我是存储过程的新手，我想通过使用该行列来获取某行的 ID 'name'。以下是我使用的存储过程。

ALTER PROCEDURE [dbo].[SP_Get_SHGO_ID] 
    -- Add the parameters for the stored procedure here
     @TableName VARCHAR(50)
    ,@SHGO_Name VARCHAR(100)
    ,@Ret int OUT
AS
BEGIN
    SET NOCOUNT ON;

    DECLARE @Query AS NVARCHAR(MAX)
    DECLARE @SHGO_ID AS INT

    SET @Query = N'SELECT @x=ID FROM '+@TableName+' WHERE SHGO_Name=' +@SHGO_Name
    EXECUTE  sp_executesql  @Query,N'@x int out', @SHGO_ID out

    SET @Ret = @SHGO_ID
END

下面是我尝试执行它的方法。

USE [UL_SLHEV]
GO

DECLARE @return_value int,
        @Ret int

EXEC    @return_value = [dbo].[SP_Get_SHGO_ID]
        @TableName = N'dbo.SHGO',
        @SHGO_Name = N'AITKEN SPENCE',
        @Ret = @Ret OUTPUT

SELECT  @Ret as N'@Ret'

SELECT  'Return Value' = @return_value

GO

但是我收到以下错误。谁能帮我解决这个问题？

Msg 102, Level 15, State 1, Line 3
Incorrect syntax near 'SPENCE'.

谢谢。

Answer 1

添加转义单引号以使您的动态 SQL 字符串有效：

SET @Query = N'SELECT @x=ID FROM '+@TableName+' WHERE SHGO_Name=''' +@SHGO_Name + ''''

Answer 2

首先请使用参数绑定：

ALTER PROCEDURE [dbo].[SP_Get_SHGO_ID] 
    -- Add the parameters for the stored procedure here
     @TableName VARCHAR(50)  -- should be SYSNAME
    --,@schemaName SYSNAME    -- schema and table should be separated
    ,@SHGO_Name VARCHAR(100)
    ,@Ret int OUT
AS
BEGIN
    SET NOCOUNT ON;

    DECLARE @Query AS NVARCHAR(MAX)
    DECLARE @SHGO_ID AS INT

    SET @Query = N'SELECT @x=ID FROM '+@TableName+' WHERE SHGO_Name=@SHGO_Name'
    EXECUTE  sp_executesql  
        @Query
       ,N'@x int out, @SHGO_Name VARCHAR(100)'
       ,@SHGO_ID out
       ,@SHGO_Name;

    SET @Ret = @SHGO_ID
END

其次你应该使用 QUOTENAME 来保护 table 名称，第三个标识符是 SYSNAME.

的类型

在继续之前，请阅读 The Curse and Blessings of Dynamic SQL

存储过程 - 消息 102，级别 15，状态 1，第 3 行 '' 附近的语法不正确

Stored procedure - Msg 102, Level 15, State 1, Line 3 Incorrect syntax near ''

tsql

sql-server

stored-procedures

dynamic-sql