在 SDK 构建期间：environment-setup.d/ 尝试安装之间存在冲突

Question

我正在尝试为包含 Qt5 的 beaglebone 构建图像，并为此图像生成 SDK。

问题

我的问题是，构建失败 do_populate_sdk 任务以创建 SDK，并出现以下错误：

Error: Transaction check error: file /opt/poky/2.3.1/sysroots/x86_64-pokysdk-linux/environment-setup.d conflicts between attempted installs of nativesdk-cmake-3.7.2-r0.x86_64_nativesdk and nativesdk-qtbase-tools-5.8.0+git0+49dc9aa409-r0.x86_64_nativesdk

在流程的更上游，我遇到了以下错误消息：

ERROR: Could not invoke dnf. Command '/home/ubuntu/workspace/bbb/build-toaster-2/tmp/work/my_machine-poky-linux-gnueabi/my-image-dev/1.0-r0/recipe-sysroot-native/usr/bin/dnf [...] ' returned 1:
Added oe-repo repo from file:///home/ubuntu/workspace/bbb/build-toaster-2/tmp/work/my-machine-poky-linux-gnueabi/my-image-dev/1.0-r0/oe-rootfs-repo.
Last metadata expiration check: 0:00:00 ago on Wed Aug 16 11:47:27 2017 UTC.
Dependencies resolved.

我有什么

为了配置我的图像，我遵循了建议以及网络上其他地方的类似帖子。这是我的（缩短并略微修改过的）图像 bb 文件：

SUMMARY = "..."
LICENSE = "MIT"

IMAGE_LINGUAS = "en-us"

inherit core-image

# for populate_sdk to create a valid toolchain
inherit populate_sdk populate_sdk_qt5

CORE_OS = "..."
KERNEL_EXTRA_INSTALL = "..."
WIFI_SUPPORT = "..."

DEV_SDK_INSTALL = " \
    binutils \
    binutils-symlinks \
    coreutils \
    cpp \
    cpp-symlinks \
    diffutils \
    file \
    g++ \
    g++-symlinks \
    gdb \
    gdbserver \
    gcc \
    gcc-symlinks \
    gettext \
    git \
    ldd \
    libstdc++ \
    libstdc++-dev \
    libtool \
    make \
    perl-modules \
    pkgconfig \
    python-modules \
    python3-modules \
 "

DEV_EXTRAS = "..."

EXTRA_TOOLS_INSTALL = " \
    acpid \
    bc \
    bzip2 \
    cursor-blink \
    devmem2 \
    dosfstools \
    emmc-installer \
    ethtool \
    findutils \
    i2c-tools \
    iperf3 \
    htop \
    less \
    memtester \
    nano \
    netcat \
    procps \
    rsync \
    sysfsutils \
    tcpdump \
    unzip \
    util-linux \
    util-linux-blkid \
    wget \
    zip \
 "

MQTT = "..."
ROOTFS_POSTPROCESS_COMMAND += "..."

QT_TOOLS = " \
    qtbase \
    qtbase-dev \
    qtbase-mkspecs \
    qtbase-plugins \
    qtbase-tools \
    qtserialport-dev \
    qtserialport-mkspecs \
    qt5-env \
 "

QT5_PKGS = " \
    qt3d \
    qt3d-dev \
    ...
    qtxmlpatterns \
    qtxmlpatterns-dev \
    qtxmlpatterns-mkspecs \
"

FONTS = "..."
TSLIB = "... "
ADDITIONAL_PKGS = "..."
QT_TEST_APPS = "..."

IMAGE_INSTALL += " \
    ${CORE_OS} \
    ${DEV_SDK_INSTALL} \
    ${DEV_EXTRAS} \
    ${EXTRA_TOOLS_INSTALL} \
    ${KERNEL_EXTRA_INSTALL} \
    ${FONTS} \
    ${QT_TOOLS} \
    ${QT5_PKGS} \
    ${QT_TEST_APPS} \
    ${MQTT} \
    ${WIFI_SUPPORT} \
    ${TSLIB} \
    ${ADDITIONAL_PKGS} \
 "

IMAGE_FEATURES_append = " dev-pkgs"

export IMAGE_BASENAME = "my-image-dev"

我在 local.conf 中也设置了 DISTRO_FEATURES_remove = "busybox x11 wayland" 和 DISTRO_FEATURES_append = " systemd opengl aufs"。

如果我删除 inherit populate_sdk_qt5 行，构建运行良好，但当然在这种情况下我没有为我的 SDK 生成。

我发现了什么

我发现不同的人遇到了同样的问题（例如 here），但没有人得到答案。

我检查了 nativesdk-cmake 以及 nativesdk-qtbase_git 配方（均未更改标准）以查看文件的创建位置，对我来说都没有问题：

本地人-qtbase_git.bb:

fakeroot do_generate_qt_environment_file() {
    mkdir -p ${D}${SDKPATHNATIVE}/environment-setup.d/
    script=${D}${SDKPATHNATIVE}/environment-setup.d/qt5.sh

    echo 'export PATH=${OE_QMAKE_PATH_HOST_BINS}:$PATH' > $script
    echo 'export OE_QMAKE_CFLAGS="$CFLAGS"' >> $script
    echo 'export OE_QMAKE_CXXFLAGS="$CXXFLAGS"' >> $script
    echo 'export OE_QMAKE_LDFLAGS="$LDFLAGS"' >> $script
    echo 'export OE_QMAKE_CC=$CC' >> $script
    echo 'export OE_QMAKE_CXX=$CXX' >> $script
    echo 'export OE_QMAKE_LINK=$CXX' >> $script
    echo 'export OE_QMAKE_AR=$AR' >> $script
    echo 'export QT_CONF_PATH=${OE_QMAKE_PATH_HOST_BINS}/qt.conf' >> $script
    echo 'export OE_QMAKE_LIBDIR_QT=`qmake -query QT_INSTALL_LIBS`' >> $script
    echo 'export OE_QMAKE_INCDIR_QT=`qmake -query QT_INSTALL_HEADERS`' >> $script
    echo 'export OE_QMAKE_MOC=${OE_QMAKE_PATH_HOST_BINS}/moc' >> $script
    echo 'export OE_QMAKE_UIC=${OE_QMAKE_PATH_HOST_BINS}/uic' >> $script
    echo 'export OE_QMAKE_RCC=${OE_QMAKE_PATH_HOST_BINS}/rcc' >> $script
    echo 'export OE_QMAKE_QDBUSCPP2XML=${OE_QMAKE_PATH_HOST_BINS}/qdbuscpp2xml' >> $script
    echo 'export OE_QMAKE_QDBUSXML2CPP=${OE_QMAKE_PATH_HOST_BINS}/qdbusxml2cpp' >> $script
    echo 'export OE_QMAKE_QT_CONFIG=`qmake -query QT_INSTALL_LIBS`${QT_DIR_NAME}/mkspecs/qconfig.pri' >> $script
    echo 'export OE_QMAKE_PATH_HOST_BINS=${OE_QMAKE_PATH_HOST_BINS}' >> $script
    echo 'export QMAKESPEC=`qmake -query QT_INSTALL_LIBS`${QT_DIR_NAME}/mkspecs/linux-oe-g++' >> $script

    # Use relocable sysroot
    sed -i -e 's:${SDKPATHNATIVE}:$OECORE_NATIVE_SYSROOT:g' $script
}

cmake-3.7.2.bb:

do_install_append_class-nativesdk() {
    mkdir -p ${D}${datadir}/cmake
    install -m 644 ${WORKDIR}/OEToolchainConfig.cmake ${D}${datadir}/cmake/

    mkdir -p ${D}${SDKPATHNATIVE}/environment-setup.d
    install -m 644 ${WORKDIR}/environment.d-cmake.sh ${D}${SDKPATHNATIVE}/environment-setup.d/cmake.sh
}

environment.d-cmake.sh:

alias cmake="cmake -DCMAKE_TOOLCHAIN_FILE=$OECORE_NATIVE_SYSROOT/usr/share/cmake/OEToolchainConfig.cmake"

为了尝试，我继续执行了
/home/ubuntu/workspace/bbb/build-toaster-2/tmp/work/my_machine-poky-linux-gnueabi/my-image-dev/1.0-r0/recipe-sysroot-native/usr/bin/dnf
脚本来自
/home/ubuntu/workspace/bbb/build-toaster-2/tmp/work/my_machine-poky-linux-gnueabi/my-image-dev/1.0-r0/recipe-sysroot-native
这让我收到以下错误消息：

Traceback (most recent call last):  
File "/home/ubuntu/workspace/bbb/build-toaster-2/tmp/work/my-machine-poky-linux-gnueabi/my-image-dev/1.0-r0/recipe-sysroot-native/usr/bin/dnf.real", line 57, in <module>  
    from dnf.cli import main  
ImportError: No module named 'dnf'

虽然 dnf 模块似乎存在:

<path as above>/recipe-sysroot-native$ find -name dnf
./usr/lib/python3.5/site-packages/dnf
./usr/bin/dnf
./etc/dnf
./etc/bash_completion.d/dnf
./etc/logrotate.d/dnf

你能看出我做错了什么吗？我真是一窍不通...

Answer 1

Edit: Anders' provides a more elegant solution by switching the packaging class. If you can, check out his approach before trying this workaround.

我找到了一个适合我的解决方法，但不是理想的解决方案。无论如何我都会发布它，以防它对某人有帮助：

我想通了，nativesdk-cmake 包以某种方式与 Qt 包发生了冲突。为此，我在自定义图层中创建了一个 nativesdk-packagegroup-sdk-host.bbappend 文件，内容如下：

RDEPENDS_${PN}_remove = "\
    nativesdk-cmake \
"

这从 SDK 构建中删除了 cmake 依赖项，这对我的目的有效。但这只能解决症状而不是问题。所以我很高兴有任何其他解决方案。

Answer 2

我正在使用 cmake 和 Qt5 构建 SDK，没有任何问题...

您的问题似乎源于 dnf，并且由于我使用 ipk 进行构建没有任何问题，因此 OpenEmbedded 中的 rpm 处理很可能存在错误.

你能尝试重建：

PACKAGE_CLASSES = "package_ipk"

在您的 local.conf 中看到它有帮助吗？

Answer 3

只需尝试在 nativesdk-qtbase.bb 中添加 DIRFILES = ""（您应该使用 DIRFILES = "" 在您的自定义层中设置干净整洁的 nativesdk-qtbase.bbappend）。这解决了由于此 RPM 的 RPM 目录所有权引起的冲突，这是标准 RPM 打包中的默认策略。详见package_rpm.bbclass@pythonwrite_specfile(){....walk_files方法。注意：DIRFILES 必须定义但留空才能在当前包上工作。瞧。

干杯。

Answer 4

RPM 对 files/directories 进行了严格检查。 environment-setup.d 您问题中的目录可能在 2 个包之间有不同的模式或用户。

您可以检查函数 rpmfilesCompare 以了解 RPM 执行的确切检查。

Answer 5

正如 so61pi 提到的，RPM 对 files/directories 有严格的检查。就我而言，安装 nativesdk-qtbase 后 environment.d 文件夹的权限为 775，而 nativesk-cmake 创建的同一文件夹的权限为 755。

我不知道这是否是由于函数 generate_qt_environment_file 在 fakeroot 环境中执行造成的，但我通过将其函数体添加到 do_install 来修复它函数并删除 generate_qt_environment_file.

但不确定这是否是正确的修复方法。我注意到其他一些食谱使用了 fakeroot 关键字，而另一些则没有。我想知道为什么...

在 SDK 构建期间：environment-setup.d/ 尝试安装之间存在冲突

During SDK build: environment-setup.d/ conflicts between attempted installs

bitbake

yocto

问题

我有什么

我发现了什么