从一组逗号分隔值中获取列的计数？

Question

我有两列，我想获得一个唯一地点列表以及下一列计数的总和。

例如：

当前

Places (ColumnA)                  Count(ColumnB)
Italy, Greece, France             10
Italy, Greece                     5
France                            1

期望的结果

Places (ColumnD)                  Count(ColumnE)
Italy                             15
Greece                            15
France                            11

Answer 1

假设您的数据从第 2 行开始，请在 D2 中尝试：

=ArrayFormula({unique(trim(transpose(split(concatenate(A2:A&","),",")))),sumif(A2:A, "=*"&unique(trim(transpose(split(concatenate(A2:A&","),","))))&"*",B2:B)})

或者，或者：

=query(ArrayFormula({transpose(split(query(substitute(A2:A,",",""),,50000)," ")),transpose(split(concatenate(rept(B2:B&char(9), len(A2:A)-len(substitute(A2:A, ",",""))+1 )),char(9)))}), "select Col1, sum(Col2) where Col1 <>'' group by Col1 label sum(Col2)'' ")

另一种方式（这归功于 AdamL）：

=ArrayFormula(QUERY(TRANSPOSE(SPLIT(QUERY(REPT(A2:A&", ",B2:B),,ROWS(A2:A)),", "))&{"",""},"select Col1, count(Col2) group by Col1 label count(Col2) ''",0))

从一组逗号分隔值中获取列的计数？

Getting the count of a column from a set of comma separated values?

google-sheets