kdb/q 如何从列表中删除条目

Question

我正在尝试将多个 csv 与相同的列连接起来。

getDataFromCsv :{[fn];
    if[not () ~key hsym fn; data: ("zSzzSISSIIIIIffffff"; enlist "\t") 0:fn;
    ... do stuff...
    :data];}

getFiles:{[dates;strat];root:"/home/me/data_";:{x: `$x, ssr[string y; "."; ""], ".csv"}[root] each dates;}


getData:{[dates;strat];`tasks set ([]c:());files:getFiles[dates;strat];:getDataFromCsv each files;}

这样做我得到了一个 table 的列表，其中一些条目是空的，没有文件

[0] = ([] c1;c2;c2 ...
[1] = ([] c1;c2;c2 ...
[2] = ([] c1;c2;c2 ...
[3] = ([] c1;c2;c2 ...
[4] = ([] c1;c2;c2 ...
[5] = ::
[6] = ([] c1;c2;c2 ...

有了这些条目，我无法通过删除列表来获得包含所有条目的 table。我怎样才能删除那些空条目？

Answer 1

您可以从列表中删除类型不是 98h 的快速修复，假设列表中不包含其他数据类型：

q)r
::
+`a`b`c!(41 48 29;2 8 6;5 8 5)
+`a`b`c!(41 48 29;2 8 6;5 8 5)
+`a`b`c!(41 48 29;2 8 6;5 8 5)
q)raze @[r;where 98h=type each r]
a  b c
------
41 2 5
48 8 8
29 6 5
41 2 5
48 8 8
29 6 5
41 2 5
48 8 8
29 6 5

这还假设每个输出的所有列都相同。如果不是，您可以使用 uj 来合并列：

q)t:r,enlist ([] d:1 2 3; e:3 4 5)
q)(uj/)@[t;where 98h=type each t]
a  b c d e
----------
41 2 5
48 8 8
29 6 5
41 2 5
48 8 8
29 6 5
41 2 5
48 8 8
29 6 5
       1 3
       2 4
       3 5

Answer 2

个人...

如果你有“...做东西...”或“：数据”，我会简单地检查数据计数或添加类似的检查。如果 count=0 那么 return 一个空列表 '()' 而不是你当前在函数中 return 的通用 null '(::)'。

通用 null 是这里的问题，这就是您要解决的问题。

下面的例子...

// example returning generic null
q){if[x~0;:(::)];([]2?10)}each 1 0 3
+(,`x)!,4 4
::
+(,`x)!,7 9
q)raze {if[x~0;:(::)];([]2?10)}each 1 0 3
(,`x)!,6
(,`x)!,2
::
(,`x)!,9
(,`x)!,2

// put a check in against 'data' to return an empty list if count=0 or similar
q){if[x~0;:()];([]2?10)}each 1 0 3
+(,`x)!,3 2
()
+(,`x)!,1 8
// your raze works now
q)raze {if[x~0;:()];([]2?10)}each 1 0 3
x
-
3
1
7
2

kdb/q 如何从列表中删除条目

kdb/q how to drop entries from lists

kdb