VB.Net 表单应用程序数据库 table 更新

Question

我正在尝试制作一个小应用程序，允许用户阅读描述仓库库存的 table 的内容，根据指示物品所在仓库的 2 行以及分配的条码进行搜索我已经设法通过使用绑定源和数据网格视图开始工作，通过将条形码和位置作为来自两个框的字符串的查询来更新视图。

为了让这个应用程序适合我的基本 objective，我需要的第二部分是添加新行并将它们存储到数据库中的原始 table 中，以便用户可以直接独立于仓库添加新项目。

到目前为止，我遇到了 2 个问题：我需要一个表示顺序 ID 的主键，但我不知道如何生成顺序递增的 ID，我设法通过使用 top 1 order by desc 查询组合，但数据在添加新行后没有得到更新，产生错误，因为它试图添加另一行具有相同主键值的行。我遇到的第二个问题是：gridview 根据我在文本框中输入的数据进行相应更改我设置为收集 table 的各种值，但数据库本身的 table 未显示任何更改，只保留我在创建时输入的测试数据。

Public Class AddItems
    Private Sub AddItems_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        'TODO: This line of code loads data into the 'MagazzinoDataSet.LastUsedID' table. You can move, or remove it, as needed.
        Me.LastUsedIDTableAdapter.LastUsedID(Me.MagazzinoDataSet.LastUsedID)
        'TODO: This line of code loads data into the 'MagazzinoDataSet.Stock' table. You can move, or remove it, as needed.
        Me.StockTableAdapter.Fill(Me.MagazzinoDataSet.Stock)
        'TODO: This line of code loads data into the 'MagazzinoDataSet.AddWarehouseList' table. You can move, or remove it, as needed.
        Me.AddWarehouseListTableAdapter.AddWarehouseList(Me.MagazzinoDataSet.AddWarehouseList)
        'TODO: This line of code loads data into the 'MagazzinoDataSet.WarehouseList' table. You can move, or remove it, as needed.
        Me.WarehouseListTableAdapter.Fill(Me.MagazzinoDataSet.WarehouseList)
        'TODO: This line of code loads data into the 'MagazzinoDataSet.Stock' table. You can move, or remove it, as needed.
        Me.StockTableAdapter.Fill(Me.MagazzinoDataSet.Stock)
    End Sub
     Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

    Dim R As DataRow = MagazzinoDataSet.Tables("Stock").NewRow()

    R("Supplier") = Supplier.Text
    R("Producer_code") = ProducerCode.Text
    R("Barcode") = Barcode.Text
    R("Comp_name") = ComponentName.Text
    R("Warehouse") = Warehouse.Text
    R("Internal_Code") = InternalCode.Text
    R("Description_IT") = ITDescr.Text
    R("Description_EN") = ENDescr.Text
    'R("ID") = NextID.SelectedValue <- this would be an hidden uneditable multibox containing the product of the query finding the next value to be inserted in the table (basically last ID + 1, nothing fancy)"ID" would be the primary key of this table
    R("Quantity") = "0"

    MagazzinoDataSet.Tables("Stock").Rows.Add(R)
    DataGridView1.DataSource = MagazzinoDataSet.Stock

End Sub
End Class

总结一下：

我将如何更新数据库 table 以包含新行？
有没有一种聪明的方法来找到最后一个值，将其递增 1 以获得下一个值并在插入新行时更新它，以免以主键具有相同值的 2 行结束，产生错误？

Answer 1

要在 Db 中设置增量 ID，假设您有权访问 SQL Server Management Studio，在 table 的设计中，对于 ID 列，在列属性中，向下滚动到身份规范并将（是身份）设置为是。

要添加新行，我使用以下代码：

Using NotesDS As New DataSet
    Using NotesDA As New SqlDataAdapter With {.SelectCommand = New SqlCommand With {.Connection = SQLDBConnection, .CommandText = "SELECT * FROM Notes WHERE ID = " & ID}}
        NotesDA.Fill(NotesDS, "Notes")
        Using NotesDV As New DataView(NotesDS.Tables("Notes"))
            Using NoteBuilder As New SqlCommandBuilder(NotesDA) With {.QuotePrefix = "[", .QuoteSuffix = "]"}                        
                If NotesDV.Count = 0 Then                             
                    Dim NoteDRV As DataRowView = NotesDV.AddNew                       
                    NoteDRV.Item("UserName") = UserName
                    NoteDRV.Item("Note") = Note
                    NoteDRV.Item("NoteDate") = NoteDate
                    NoteDRV.Item("CompanyCode") = CompanyCode
                    NoteDRV.EndEdit()
                    NotesDA.UpdateCommand = NoteBuilder.GetUpdateCommand
                    NotesDA.Update(NotesDS, "Notes")
                End If
            End Using
        End Using
    End Using
End Using

显然，进行修改以适合您的 table 和列名。

如果您需要检索 ID 以进行显示，您可以向更新添加处理程序，例如：

Public Sub GenericOnRowUpdated(sender As Object, e As System.Data.SqlClient.SqlRowUpdatedEventArgs)        
    Dim newID As Integer = 0
    Dim idCMD As SqlClient.SqlCommand = New SqlClient.SqlCommand("SELECT @@IDENTITY", SQLDBConnection)
    If e.StatementType = StatementType.Insert Then            
        newID = CInt(idCMD.ExecuteScalar())
        e.Row("ID") = newID
    End If
End Sub

并像这样使用：

 AddHandler NotesDA.RowUpdated, New SqlRowUpdatedEventHandler(AddressOf GenericOnRowUpdated)
 NotesDA.Update(NotesDS, "Notes")
 NewID = NoteDRV.Item("ID")

编辑

第一个示例修改并解释如下：

'Declare you connection to the SQL dB. Connection String looks like "Data Source=192.168.71.10\dBName; Initial Catalog=dBName; User ID=USER; Password='PASSWORD!';MultipleActiveResultSets=true"  -  You may well already have an open connection, and can use that instead. Not sure what your 
StockBindingSource is...
    Dim oConn As New SqlConnection("CONNECTION STRING")
    'Open the connection
    oConn.Open()
    'Declare Your DataAdapter and initialise using your connection
    Dim DA As New SqlDataAdapter With {.SelectCommand = New SqlCommand With {.Connection = oConn, .CommandText = "SELECT * FROM Stock WHERE ID=0"}}
    'Declare you DataSet
    Dim DS As New DataSet
    'Fill Your DataSet with the Stock table from your DataAdapter
    DA.Fill(DS, "Stock")
    'Declare a DataView for easy use (really the same as using DS.Tables("Stock").DefaultView)
    Dim DV As New DataView(DS.Tables("Stock"))
    'Declare a CommandBuilder and initialise with your DataAdapter. This will now watch for changes made to your data and build the appropriate SQL UPDATE/INSERT/DELETE command. the "[" and "]" are in case any column names use reserved words
    Dim Builder As New SqlCommandBuilder(DA) With {.QuotePrefix = "[", .QuoteSuffix = "]"}
    'Decalre a DataRowView for data population, based on your DataView table structure
    Dim R As DataRowView = DV.AddNew()
    'Populate the fileds with your Form data
    R("Supplier") = Supplier.Text
    R("Producer_code") = ProducerCode.Text
    R("Barcode") = Barcode.Text
    R("Comp_name") = ComponentName.Text
    R("Warehouse") = Warehouse.Text
    R("Internal_Code") = InternalCode.Text
    R("Description_IT") = ITDescr.Text
    R("Description_EN") = ENDescr.Text
    R("Quantity") = "0"
    'Notify that the edit has finished
    R.EndEdit()
    'Get the SQL command from the CommandBuilder 
    DA.UpdateCommand = Builder.GetUpdateCommand()
    'Execute the update (in this case it will be an INSERT) 
    DA.Update(DS, "Stock")

VB.Net 表单应用程序数据库 table 更新

VB.Net forms application database table update

vb.net

sql-server

visual-studio-2015