从一个工作表复制单元格范围并粘贴到另一个工作表中作为值而不是公式

Question

我在下面使用此代码复制一系列单元格并粘贴到不同工作表上的下一个可用行。我的问题是它粘贴的是公式而不是值。我需要更改什么？

Private Sub CopyAuditData_Click()
Dim ws1 As Worksheet, ws2 As Worksheet
    Dim DestRow As Long
    Set ws1 = Sheets("Call Audit Sheet")
    Set ws2 = Sheets("HiddenData")
    DestRow = ws2.Cells(Rows.Count, "A").End(xlUp).Row + 1
    ws1.Range("V1").Copy ws2.Range("A" & DestRow)
    ws1.Range("V2").Copy ws2.Range("B" & DestRow)
    ws1.Range("V3").Copy ws2.Range("C" & DestRow)
    ws1.Range("V4").Copy ws2.Range("D" & DestRow)
    ws1.Range("V5").Copy ws2.Range("E" & DestRow)
    ws1.Range("V6").Copy ws2.Range("F" & DestRow)
    ws1.Range("V7").Copy ws2.Range("G" & DestRow)
    ws1.Range("V8").Copy ws2.Range("H" & DestRow)
    ws1.Range("V9").Copy ws2.Range("I" & DestRow)
    ws1.Range("V10").Copy ws2.Range("J" & DestRow)
    ws1.Range("V11").Copy ws2.Range("K" & DestRow)
    ws1.Range("V12").Copy ws2.Range("L" & DestRow)
    ws1.Range("V13").Copy ws2.Range("M" & DestRow)
    ws1.Range("V14").Copy ws2.Range("N" & DestRow)
    ws1.Range("V15").Copy ws2.Range("O" & DestRow)
    ws1.Range("V16").Copy ws2.Range("P" & DestRow)
    ws1.Range("V17").Copy ws2.Range("Q" & DestRow)
    ws1.Range("V18").Copy ws2.Range("R" & DestRow)
    ws1.Range("V19").Copy ws2.Range("S" & DestRow)
    ws1.Range("V20").Copy ws2.Range("T" & DestRow)
    ws1.Range("V21").Copy ws2.Range("U" & DestRow)
    ws1.Range("V22").Copy ws2.Range("V" & DestRow)
    ws1.Range("V23").Copy ws2.Range("W" & DestRow)
    ws1.Range("V24").Copy ws2.Range("X" & DestRow)
    ws1.Range("V25").Copy ws2.Range("Y" & DestRow)
End Sub

在此先感谢大家。

Answer 1

而不是

ws1.Range("V1").Copy ws2.Range("A" & DestRow)

做

ws1.Range("V1").Copy
ws2.Range("A" & DestRow).PasteSpecial Paste:=xlPasteValues

注意：现在必须是2行代码！

Answer 2

试试这个只复制值：

而不是

ws1.Range("V1").Copy ws2.Range("A" & DestRow)

使用

ws2.Range("A" & DestRow) = ws1.Range("V1")

Answer 3

这实际上是将一个工作表的行转列到另一个工作表。

而不是 copy/paste 的许多行具有特定范围，使用循环，将 25-50 行减少为 3。

要在您的具体示例中使用，因为您恰好将行转列。行号恰好与您要粘贴到的列号相匹配，因此请将其包含在一个循环中。

Private Sub CopyAuditData_Click()

Dim ws1 As Worksheet, ws2 As Worksheet
Dim DestRow As Long, lRow As Long

    Set ws1 = Sheets("Call Audit Sheet")
    Set ws2 = Sheets("HiddenData")
    DestRow = ws2.Cells(Rows.Count, "A").End(xlUp).Row + 1

    'CHANGES HERE
    For lRow = 1 To 25
        ws2.Cells(DestRow, lRow).Value = ws1.Cells(lRow, "V").Value 
    Next lRow

End Sub

分解如下：

其中lRow = 1将其同时用作源的行和目标的列。

ws2.Cells(DestRow, 1) 等同于 ws2.Range("A" & DestRow)

ws1.Cells(lRow, "V") 等同于 ws1.Range("V1")

从一个工作表复制单元格范围并粘贴到另一个工作表中作为值而不是公式

Copy cell range from one worksheet and paste in a different worksheet as a value rather than formula

excel

vba