如何获得可用的加速度计读数

Question

我有一个基于 arduino 的设备 (Teensy 3.2)，我正在尝试从 H3LIS331DL 加速度计分线板上读取数据。我可以写入加速度计上的控制寄存器并从数据寄存器中读取，但我无法获得稳定、有用的数据。

首先，有用的数据。加速度计芯片的数据 sheet 只是表示数据寄存器 "X-axis acceleration data. The value is expressed as two’s complement." SparkFun LIS331 库表示 "The data that comes out is 12-bit data, left justified, so the lower four bits of the data are always zero." 如果数据是每轴 12 位，我猜输出（适当条件）应该是 0-4095，零 G 大约是 2048，但这与我得到的不匹配。加速度计现在坐在我的桌子上，X 轴和 Y 轴给出高端和低端的读数（0-19 或 4063-4095），Z 轴给出 9-80 的读数（始终低于 2048任何方向）。

我对数据的期望是错误的，还是我做了什么没有得到正确的数据？

第二，稳定的数据。此加速度计的低设置为 +/- 100G 范围。我目前的工作台测试是在 -1G 到 +1G（全范围的 1%），所以我希望输出数据的范围成比例地小，但是从一个恒定位置开始的输出范围已经几乎是全范围的 2%规模。

怎样才能得到更稳定的输出数据？

#include <i2c_t3.h>

#define ACCEL_NEW_PIN    16

#define CTRL_REG1        0x20
#define CTRL_REG2        0x21
#define CTRL_REG3        0x22
#define CTRL_REG4        0x23
#define OUT_X_L          0x28
#define OUT_X_H          0x29
#define OUT_Y_L          0x2A
#define OUT_Y_H          0x2B
#define OUT_Z_L          0x2C
#define OUT_Z_H          0x2D

#define accelAddress     0x19

volatile bool accelNew = true;
int16_t x, y, z;

void setup() {
  delay(1000);
  Serial.begin(115200);
  Serial.println("hello, world!");
  accelSetup();
}

void loop(){
  if(accelNew){
    getAccel(x, y, z);
    Serial.println(x);
    Serial.println(y);
    Serial.println(z);
    accelNew = false;
  }
}

void accelSetup(){
  Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 1800000, I2C_OP_MODE_IMM);
  writeAccel(CTRL_REG1, B00111111); //normal mode, 1000Hz, X, Y and Z enabled
  writeAccel(CTRL_REG2, B00110000); //high pass filter enabled
  writeAccel(CTRL_REG3, B00000010); //Data ready output pin enabled
  writeAccel(CTRL_REG4, B10000000); //Block data update enabled, 100G range
  pinMode(ACCEL_NEW_PIN,INPUT);
  attachInterrupt(digitalPinToInterrupt(ACCEL_NEW_PIN), accelISR, RISING);
}

void accelISR(){
  accelNew = true;
}

void getAccel(int16_t& xAccel, int16_t& yAccel, int16_t& zAccel){
  uint8_t data[6];
  readAccel(OUT_X_L, data, 6);
  xAccel = (data[0] | data[1] << 8) >> 4;
  yAccel = (data[2] | data[3] << 8) >> 4;
  zAccel = (data[4] | data[5] << 8) >> 4;
}

void readAccel(byte address, byte* data, uint8_t bytes)
{
  Wire.beginTransmission(accelAddress);
  Wire.write(address | 0x80);//
  Wire.sendTransmission();
  Wire.sendRequest(accelAddress, bytes);
  while(Wire.available()) *(data++) = Wire.readByte();
}

void writeAccel(byte address, byte data)
{
  Wire.beginTransmission(accelAddress);
  Wire.write(address);
  Wire.write(data);
  Wire.endTransmission();
}

Answer 1

我基本上找到了问题的答案。数据寄存器字节 do 需要按照我的方式组合并右移，但它需要 signed 右移，而我的代码相当于 unsigned 右移。符号位被误解为值位，并且在数字应该为负数时将结果值发送到范围的顶部。在移位之前将组合的 unsigned bytes 转换为 signed int 解决了该问题并使输出数据更有意义。

xAccel = (int16_t)(data[0] | data[1] << 8) >> 4;

好消息是所有 3 个轴现在都根据方向吐出具有相同线性斜率的有意义的数据。

坏消息是每个轴在 0G 时与 0 有不同的偏移量，并且每个轴仍然有一个 variance/jitter 大约 +/- 18 的平均值（比我想要的要高） ).

如何获得可用的加速度计读数

How to get usable accelerometer readings

c++

arduino

accelerometer