如何在记录结构中声明联合？

Question

我正在尝试定义 TWaveFormatExtensible 类型，但我不确定我是否正确声明了 Samples 联合。这是头文件 (Windows SDK 10.0.17763.0) 中的原始声明：

typedef struct {
    WAVEFORMATEX    Format;
    union {
        WORD wValidBitsPerSample;       /* bits of precision  */
        WORD wSamplesPerBlock;          /* valid if wBitsPerSample==0 */
        WORD wReserved;                 /* If neither applies, set to zero. */
    } Samples;
    DWORD           dwChannelMask;      /* which channels are */
                                        /* present in stream  */
    GUID            SubFormat;
}

这就是我尝试过的：

type
  TWAVEFORMATEX = record
    wFormatTag: Word;
    nChannels: LongWord;
    nSamplesPerSec: Word;
    nAvgBytesPerSec: LongWord;
    nBlockAlign: Word;
    wBitsPerSample: Word;
    cbSize: Word;
  end;

  TWaveFormatExtensible = record
    Format: TWAVEFORMATEX;
    dwChannelMask: LongWord;
    SubFormat: Integer;
    case Word of
      0: (wValidBitsPerSample: Word;);
      1: (wSamplesPerBlock: Word;);
      2: (wReserved: Word;);
  end;

但这是不正确的。如何在 Delphi 中的记录结构中声明联合？

Answer 1

结构字段的顺序必须与原始 (C++) 声明中的顺序相同。但是有一个问题：原始声明将 Samples 变体放在记录的中间，而这在 Delphi 中是不允许的。

您可以通过将变体部分声明为单独的记录来解决此问题，然后将该记录作为字段包含在最终结构中。

TWaveFormatExtensibleSamples = record
case Word of
  0: (wValidBitsPerSample: Word;);
  1: (wSamplesPerBlock: Word;);
  2: (wReserved: Word;);
end;

然后构建最终结构：

TWaveFormatExtensible = record
  Format: TWAVEFORMATEX;
  Samples: TWaveFormatExtensibleSamples;
  dwChannelMask: DWORD;
  SubFormat: TGUID; 
end;

edit：带有变体部分的记录的文档，状态：

A record type can have a variant part, which looks like a case statement. The variant part must follow the other fields in the record declaration.

这涉及没有封闭记录声明的变体部分。

然而，正如 Remy Lebeau 指出的那样，带有变体部分的 record 可以直接在 TWaveFormatExtensible 声明中声明为结构的一部分，在其他之间字段：

TWaveFormatExtensible = record
  Format: TWAVEFORMATEX;
  Samples: record
    case Word of
    0: (wValidBitsPerSample: Word;);
    1: (wSamplesPerBlock: Word;);
    2: (wReserved: Word;);
  end;
  dwChannelMask: DWORD;
  SubFormat: TGUID;
end;

所以这可以与单独声明的 TWaveFormatExtensibleSamples 记录一起使用。

如何在记录结构中声明联合？

How to declare union inside a record structure?

delphi

winapi

delphi-7