批处理文件：子字符串出现后解析字符串，而不是定界符

Question

我有，批处理文件脚本显示了 adb 实用程序的输出。

FOR /F "skip=1 delims=~" %%x IN ('adb devices -l') DO echo %%x

2 条输出线

0123456789ABCDEF       device product:java_joyplus_qb7 model:TM702B4_3G device:java_joyplus_qb7 transport_id:12
F9NPFP084096           device product:WW_P023 model:P023 device:P023_1 transport_id:11

我想在 "transport_id:" 之后解析非 space 子字符串。对于第一行，我想要 12，对于第二行，我想要 11。我该怎么做？

Answer 1

如果我理解正确，下面的batch-file应该输出你需要的信息。

@Echo Off

For /F "Skip=1 Tokens=1*" %%G In ('adb.exe devices -l') Do (Set "DI=%%H"
    SetLocal EnableDelayedExpansion
    For /F %%I In ("!DI:*transport_id:=!") Do EndLocal & Echo %%I)

Pause

而且，如果您想从 cmd 开始：

For /F "Skip=1Tokens=1*" %G In ('adb.exe devices -l')Do @Set "DI=%H"&For /F %I In ('Cmd /D/V/C Echo "!DI:*transport_id:=!"')Do @Echo %~I

Answer 2

您可以轻松提取所有变量，无论它们的位置如何，并显示您想要的内容：

@echo off
setlocal EnableDelayedExpansion

FOR /F "skip=1 delims=" %%a IN ('adb devices -l') DO (
   for %%b in (%%a) do for /F "tokens=1,2 delims=:" %%x in ("%%b") do set "%%x=%%y"

   echo Product=!product!
   echo Transport=!transport_id!
)

例如：

Product=java_joyplus_qb7
Transport=12
Product=WW_P023
Transport=11

Answer 3

SETLOCAL EnableDelayedExpansion
REM … 
FOR /F "skip=1 delims=~" %%x IN ('adb devices -l') DO (
    set "_ID="&set "_transport_id="
    call :parse "" "%%~x"
    echo transport_id !_transport_id!  (!_ID!^)
)

REM … remaining part of your script here …

goto :eof

:parse
if "%~2"=="" goto :eof 
for /F "tokens=1,*" %%G in ("%~2") do (
  if "%~1"=="" (
    set "_ID=%%~G"
    call :parse "%%~G" "%%~H" 
  ) else (
    for /F "tokens=1,2 delims=: " %%g in ("%~2") do (
      if /I "%%~g"=="transport_id" (
        set "_transport_id=%%~h"
      ) else (
        call :parse "%%~G" "%%~H" 
      )
    )
  )  
)
goto :eof

使用以下脚本和硬编码假设 adb 输出进行测试（未安装 adb）：

@ECHO OFF
SETLOCAL EnableExtensions EnableDelayedExpansion
(
REM last token
set "_ID="&set "_transport_id="
call :parse "" "0123456789ABCDEF       device product:java_joyplus_qb7 model:TM702B4_3G device:java_joyplus_qb7 transport_id:12"
echo transport_id !_transport_id!  (!_ID!^)
REM penult token
set "_ID="&set "_transport_id="
call :parse "" "F9NPFP084096           device product:WW_P023 model:P023 transport_id:11 device:P023_1"
echo transport_id !_transport_id!  (!_ID!^)
REM elsewhere token
set "_ID="&set "_transport_id="
call :parse "" "abc123def567           transport_id:10 device product:XX_P023 model:P023 device:P023_2"
echo transport_id !_transport_id!  (!_ID!^)
REM nowhere token
set "_ID="&set "_transport_id="
call :parse "" "noTransportId          sport_id:10 device product:XX_P023 model:P023 device:P023_2"
echo transport_id !_transport_id!  (!_ID!^)
)
goto :eof

:parse
if "%~2"=="" goto :eof 
for /F "tokens=1,*" %%G in ("%~2") do (
  if "%~1"=="" (
    set "_ID=%%~G"
    call :parse "%%~G" "%%~H" 
  ) else (
    for /F "tokens=1,2 delims=: " %%g in ("%~2") do (
      if /I "%%~g"=="transport_id" (
        set "_transport_id=%%~h"
      ) else (
        call :parse "%%~G" "%%~H" 
      )
    )
  )  
)
goto :eof

输出：D:\bat\SO588773.bat

transport_id 12  (0123456789ABCDEF)
transport_id 11  (F9NPFP084096)
transport_id 10  (abc123def567)
transport_id   (noTransportId)

批处理文件：子字符串出现后解析字符串，而不是定界符

batch file: Parse string after substring occurence, not delimeter

substring

batch-file

adb