XSL 在最后一个元素出现时将一个元素移动到另一个元素

Question

给定输入 XML 数据：

<Report_Entry>
    <Time_Off_Type_Group>
        <Time_Off_Type Descriptor="Sickness Full" />
    </Time_Off_Type_Group>
    <Time_Off_Type_Group>
        <Time_Off_Type Descriptor="Sickness Part" />
    </Time_Off_Type_Group>
    <Time_Off_Entry_ID>2d90199913fa9fae8</Time_Off_Entry_ID>
    <Request_or_Correction>Time Off Request</Request_or_Correction>
</Report_Entry>

因此，我希望通过条件输出数据："for-each Time_Off_Type_Group move Time_Off_Entry_ID and Request_or_Correction into the Time_Off_Type_Group"

输出示例：

<Report_Entry>
    <Time_Off_Type_Group>
        <Time_Off_Type Descriptor="Sickness Full" />
        <Time_Off_Entry_ID>2d90199913fa9fae8</Time_Off_Entry_ID>
        <Request_or_Correction>Time Off Request</Request_or_Correction>
    </Time_Off_Type_Group>
    <Time_Off_Type_Group>
        <Time_Off_Type Descriptor="Sickness Part" />
        <Time_Off_Entry_ID>2d90199913fa9fae8</Time_Off_Entry_ID>
        <Request_or_Correction>Time Off Request</Request_or_Correction>
    </Time_Off_Type_Group>
</Report_Entry>

Answer 1

认为模板不是 for-each，因此为 Time_Off_Type_Group 元素编写一个模板，将兄弟姐妹复制为子元素，并确保默认身份复制不适用于这些兄弟姐妹：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="2.0">

  <xsl:output indent="yes"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Time_Off_Type_Group">
      <xsl:copy>
          <xsl:copy-of select="*, ../(* except Time_Off_Type_Group)"/>
      </xsl:copy>
  </xsl:template>

  <xsl:template match="Report_Entry/*[not(self::Time_Off_Type_Group)]"/>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/bEzkTcn

Answer 2

或很快：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/Report_Entry">
    <xsl:variable name="common" select="Time_Off_Entry_ID | Request_or_Correction" />
    <xsl:copy>
        <xsl:for-each select="Time_Off_Type_Group">
            <xsl:copy>
                <xsl:copy-of select="* | $common"/>
            </xsl:copy>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

XSL 在最后一个元素出现时将一个元素移动到另一个元素

XSL Move one level Element into other while last one is appearing

xslt

xslt-2.0