将数字范围转换为逗号分隔列表（经典 ASP）

Question

似乎是一个非常常见的问题，但尚未找到经典 ASP 示例。

我从我们继承的数据库中获得如下所示的数据：

120-128,10,20,30,12-19

我需要能够将其转换为以逗号分隔的列表，按连续顺序，不仅提取当前的数字，还提取范围内的数字（由 - 指定）

所以在上面的例子中，我希望输出：

10,12,13,14,15,16,17,18,19,20,30,120,121,122,123,124,125,126,127,128

然后我希望能够将该结果存储为单个变量，这样我以后可以用它做更多的工作。

我找到了 Python 方法、C#、Javascript、PHP 等，但没有找到经典方法 ASP。有人可以帮忙吗？

仅供参考，永远不会有任何重复的号码，每个号码都是唯一的。

Answer 1

执行此操作的基本步骤是

用逗号分隔您的初始列表
遍历每一项，检查是否有连字符
如果有连字符，则从头到尾循环，并将该值添加到数组中，如果没有连字符，则只添加该值

到那时，您将获得所有值的列表，这些值未排序且不唯一。

在经典 ASP 中，您可以使用 Arraylist 来帮助排序和唯一性。创建两个数组列表对象。一个将包含非唯一列表，然后另一个将包含您最终的唯一列表。

<!DOCTYPE html>
<html xmlns="http://www.w3.org/1999/xhtml" lang="en">
<body>
    <p>
        <%

    v="120-128,10,20,30,12-19,13-22" 'our original string to parse

    set uniqueList=CreateObject("System.Collections.ArrayList") 'final unique list
    set mynumbers=CreateObject("System.Collections.ArrayList")  'a working list

    'first split the values by the comma
    splitCom=Split(v, ",")

    'now go through each item
    for itemnumber=0 to ubound(splitCom)
        itemToAdd=splitCom(itemnumber)
       
        if InStr(itemToAdd, "-")>0 then  'if the item has a hyphen, then we have a range of numbers
            rangeSplit=Split(itemToAdd, "-")

            for itemToAdd=rangeSplit(0) to rangeSplit(1)
                mynumbers.Add CInt(itemToAdd)
            next
        else
            mynumbers.Add Cint(itemToAdd) 'otherwise add the value itself
        end if
    next

    'at this point, mynumbers contains a full list of all your values, unsorted, and non-unique.

    mynumbers.sort  'sort the list. Can't be any easier than this

    'output the non-unique list, and build a unique list while we are at it.
    Response.Write("Non-unique list<br />")

    for each item in mynumbers                      'iterate through each item
        Response.Write(item & "<br />")             'print it
            if (not uniqueList.Contains(item)) then 'is the value in our unique list?
                uniqueList.Add(item)                'no, so add it to the unique list
            end if
    next

    'now output the unique list.
    Response.Write("<br />Unique list<br />")
    for each item in uniqueList
        Response.Write(item & "<br />")
    next
        %>
    </p>
</body>
</html>

将数字范围转换为逗号分隔列表（经典 ASP）

Turn range of numbers into a comma divided list (Classic ASP)

asp-classic