Perl 函数求和增加和减少的数字量

Question

我正在尝试创建一个 Perl 代码来对数字列表求和。本质上，我想将一列数字添加到大小组中，这些大小组以 1 的增量增加到 3，然后再返回。假设数字列表如下：

0
0.2
0.4
0.01
0.5
0.7
0.03
0.55
0.3

我想做的是增加和减少从 1 到 3 的数字数量，然后再增加和减少，所以首先只有 0，然后是 0.2+0.4，然后是 0.01+0.5+0.7，然后回到 0.03+0.55，最后只有 0.3。输出将是一个数字列表，等于以下每个括号的总和。

(0)
(0.2+0.4)
(0.01+0.5+0.7)
(0.03+0.55)
(0.3)

但是，我是 Perl 的新手，我真的不确定如何处理这个问题。任何建议将不胜感激。

Answer 1

困难的部分是确定下一组中有多少元素。为此，我们必须跟踪当前组的大小以及该数字是在增长还是在缩减。

或者我们可以将以下内容与使用模数运算符限制为数组大小的升序数一起使用：

my @group_sizes = ( 1, 2, 3, 2, 1 );

然后，这就变成了跟踪组中剩余多少元素的问题。

my $sum;
my $group_sizes_idx = 0;
my $remaining = $group_sizes[$group_sizes_idx];
for my $num (@nums) {
   $sum += $num;

   if (--$remaining == 0) {
      say $sum;   # or C<< push @sums, $sum; >>.
      $sum = undef;
      $group_sizes_idx = ( $group_sizes_idx + 1 ) % @group_sizes
      $remaining = $group_sizes[$group_sizes_idx];
   }
}

# say $sum if defined($sum);   # Uncomment this to print the sum of a partial group.

@group_sizes 可以使用

动态构建

# -2 => 3 - 2 = 1
# -1 => 3 - 1 = 2
#  0 => 3 - 0 = 3
# +1 => 3 - 1 = 2
# +2 => 3 - 2 = 1

my @group_sizes = map { $n - abs($_) } -($n-1) .. ($n-1);

或

my @group_sizes = map { $n - abs($_ - $n + 1) } 0 .. $n*2 - 2;

这意味着您可以使用以下内容：

my $sum;
my $group_sizes_idx = 0;
my $remaining = 1;
for my $num (@nums) {
   $sum += $num;

   if (--$remaining == 0) {
      say $sum;   # or C<< push @sums, $sum; >>.
      $sum = undef;
      $group_sizes_idx = ( $group_sizes_idx + 1 ) % ( $n*2 - 1 );
      $remaining = $n - abs($group_sizes_idx - $n + 1);
   }
}

# say $sum if defined($sum);   # Uncomment this to print the sum of a partial group.

Perl 函数求和增加和减少的数字量

Perl function for summing increasing and decreasing amount of numbers

scripting

perl

numbers

sum

sequence