VBA 将工作表复制到新工作簿 - with/without 个公式

Question

我使用此代码将 4 张纸复制到单独的工作簿中。其中之一 - “1”内部有公式，下面的方法会跳过这些公式。任何想法如何保持三个工作簿的价值和一个 - “1”包括公式？下面是负责该操作的部分代码。提前谢谢你。

Sub test()
Application.DisplayAlerts = False
Application.ScreenUpdating = False
Dim Fname As String, ws As Worksheet
Dim InitFileName As String, fileSaveName As String
Fname = Sheets("STRUCTURE").Range("A1").Value
Sheets(Array("STRUCTURE", "2", "3", "1")).Copy
For Each ws In ActiveWorkbook.Worksheets
    With ws.UsedRange
        .Value = .Value
    End With
Next ws
With ActiveWorkbook
fileSaveName = "FILE LOCATION FOLDER " & Sheets("STRUCTURE").Cells(1, 1) & ".xlsx"
    .SaveAs fileSaveName
    .Close
End With

Application.DisplayAlerts = True
Application.ScreenUpdating = True

End Sub

Answer 1

这是将公式更改为值的原因：

With ws.UsedRange
    .Value = .Value
End With

您有多种选择可以跳过相关工作表：

跳过名为 1 的工作表。

For Each ws In ActiveWorkbook.Worksheets
    If ws.Name <> "1" Then
        With ws.UsedRange
            .Value = .Value
        End With
   End If
Next

只遍历有问题的工作表：

Dim sheetNamesToProcess As Variant
sheetNamesToProcess = Array("STRUCTURE", "2", "3")

Dim i As Long
For i = Lbound(sheetNamesToProcess) To Ubound(sheetNamesToProcess)
    With ActiveWorkbook.Worksheets(sheetNamesToProcess(i)).UsedRange
        .Value = .Value
    End With
Next

VBA 将工作表复制到新工作簿 - with/without 个公式

VBA Copy sheets to new workbook - with/without formulas

arrays

excel

vba

copy

formula