Robot Framework：关键字 'login_resources.Open Browser' 需要 0 个参数，得到 2 个

Question

我是 Robot 框架的新手，想练习一下。我在尝试数据驱动测试时遇到了这个错误。我认为问题是资源，但我不知道出了什么问题。我搜索了一些答案，但 none 解决了它。

请帮助我。下面是我的代码。

login_resources.robot

    *** Settings ***
    Library     SeleniumLibrary

    *** Variables ***
    ${Login URL}        https://admin-demo.nopcommerce.com/login?returnurl=%2Fadmin%2F
    ${browser}      chrome

    *** Keywords ***
    Open Browser
        open browser    ${Login URL}      ${browser}
        maximize browser window

    Close Browsers
        close all browsers

    Open login page
        go to       ${Login URL}

    Input username
        [Arguments]     ${username}
        input text      id:Email      ${username}

    Input password
        [Arguments]     ${password}
        input text      id:Password     ${password}

    Click login button
        click element    xpath:/html/body/div[6]/div/div/div/div/div[2]/div[1]/div/form/div[3]/button

    Click logout button
        click link      Logout


    Error Message should be visible
        page should contain      Login was unsuccessful

    Dashboard page should be visible
        page should contain     Dashboard

DDT.robot

    *** Settings ***
    Library     SeleniumLibrary
    Resource    ../Resources/login_resources.robot
    Suite Setup     Open Browser
    Suite Teardown      Close Browsers
    Test Template       Invalid login


    *** Test Cases ***

    Right username empty password      admin@yourstore.com      ${EMPTY}
    Right username wrong password      admin@yourstore.com     xyx
    Wrong username right password      adm@yourstore.com       admin
    Wrong username empty password      adm@yourstore.com       ${EMPTY}
    Wrong username wrong password      adm@yourstore.com       xyx


    *** Keywords ***

    Invalid login
       [Arguments]     ${username}     ${password}
       Input username      ${username}
       Input password      ${password}
       Click login button
       Error Message should be visible

Answer 1

机器人框架不区分大小写。现在您有 2 个关键字，名称为 open browser。一个使用 0 个参数，另一个使用 2 个。现在您必须在使用关键字时指定库。

SeleniumLibrary.open browser

或者为您的关键字使用其他名称打开浏览器。

Robot Framework：关键字 'login_resources.Open Browser' 需要 0 个参数，得到 2 个

Robot Framework : Keyword 'login_resources.Open Browser' expected 0 arguments, got 2

resources

selenium

frameworks

robotframework