VBA 从 Class 模块（使用 Class_Initialize）中引发错误失败

Question

我一直在尝试在 class 模块中实现错误处理，这样我就可以记录用户是否遇到任何错误，以及 module/class 错误是在哪个模块中发生的。

我的方法是处理调用 sub/function 中的错误报告，并在调用 sub/function 中使用 err.raise 将错误冒泡到调用子中。

这对模块有效（从模块内部调用模块），但是当我测试从 class 模块内部引发错误时，它给了我错误 # 440 自动化错误而不是实际错误（如类型ex 不匹配）。

我将（错误？）归结为在 class_Initialize 为运行之后由于某种原因未初始化 Err 对象的事实，我使用的是 Excel 2016； Application.Version = 16。

例如，以下模块调用 class 属性:

Option Explicit

Private Sub TestCRef()

On Error GoTo ErrHandlr

    Dim y As New CellRef
    'Call y.SetRef  'normal behavior when Class_Initialize() is commented and this is used instead
    Debug.Print y.CstOrdrNo
    
Exit Sub
ErrHandlr:

    If Err.Source = ThisWorkbook.VBProject.Name Then
        Err.Source = "Module1.TestCRef"
    End If
    
    Dim ErrStr As String
    ErrStr = "Error # " & Str(Err.Number) & ", was generated by :" _
                    & Err.Source & ", Description : " & Err.Description
                    
    Debug.Print (ErrStr)
    
End Sub

class 模块 (CellRef):

Option Explicit

Public CstOrdrNo As Range
Private x As Integer
    
    
Sub Class_Initialize()

On Error GoTo ErrHandlr

    x = "Bug" 'intentional
    Set CstOrdrNo = ThisWorkbook.Worksheets(1).Range("A1")

Exit Sub
ErrHandlr:
    Err.Raise vbObjectError + 5050, "CellRef.Class_Initialize", "Error While Initializing Class"
End Sub

'Used instead of Class_Initialize
Sub SetRef()
On Error GoTo ErrHandlr

    x = "Bug" 'intentional
    Set CstOrdrNo = ThisWorkbook.Worksheets(1).Range("A1")
    
Exit Sub
ErrHandlr:
    Err.Raise vbObjectError + 5050, "CellRef.SetRef", "Error While Intializing x"
End Sub

第一种情况： Class_Initialize用于第一次调用时设置范围，出错
预期行为：- 错误 #-2147216454，生成者：CellRef.SetRef，描述：初始化时出错 Class。
发生了什么：- 错误 # 440，生成者：Module1.TestCRef，描述：自动化错误。
第二种情况： Class_Initialize 被注释掉并且使用 SetRef 代替
行为： 预期行为。

Answer 1

如您所知Class_Initialize 引发错误

440: Automation error

当其中直接出现任何错误时。

但是 Class_Initialize 可以像任何其他过程一样冒出任何错误。

所以我使用这个范例，我将 Class_Initialize 的代码放入一个新过程 ClassInitialize 并从 Class_Initialize:

调用它

Private Sub Class_Initialize()
    ClassInitialize
End Sub

Private Sub ClassInitialize()
    On Error GoTo Catch

   Any code here ...

Done:
    Exit Sub

Catch:
    Err.Raise ...
End Sub

所以我可以在 ClassInitialize 中提出我需要的任何错误，并且 Class_Initialize 会让它冒泡到它的调用者。

根据您的示例改编后的内容如下所示：

Private Sub Class_Initialize()
    ClassInitialize
End Sub

Private Sub ClassInitialize()
    On Error GoTo ErrHandlr

    x = "Bug" 'intentional
    Set CstOrdrNo = ThisWorkbook.Worksheets(1).Range("A1")

    Exit Sub

ErrHandlr:
    Err.Raise vbObjectError + 5050, "CellRef.Class_Initialize", "Error While Initializing Class"
End Sub

还要注意在 Class_Terminate 中处理运行时错误：

class 的过程 Class_Terminate 中的运行时错误（无论是否由 Err.Raise 本身引发）没有本地错误处理程序会导致无法捕获的运行时错误标准错误处理程序消息框（行为与事件处理程序相同）。

所以在 Class_Terminate 中（就像在事件处理程序中一样）总是必须启用 'local' 错误处理程序！

而且因为这个错误处理程序不能冒出错误，所以你必须在本地处理 Class_Terminate 中的运行时错误。

VBA 从 Class 模块（使用 Class_Initialize）中引发错误失败

VBA raising errors from within Class modules (with Class_Initialize) fails

error-handling

excel

vba