在 PowerBI 的另一列中为各自的组和默认值添加 "missing" 日期行？

Question

我正在使用 PowerBI 并希望汇总一段时间内的（平均）数据，但我意识到我的源数据并未反映“空”（零总计）日期值。这是有效的，并且是准确汇总一段时间内总计所必需的。

我使用以下表达式创建了一个新日期 table，以创建初步 tables 范围内的所有日期：

Date_Table = CALENDAR(MIN('SalesTable'[Daily Sales Date]),MAX('SalesTable'[Daily Sales Date]))

但是，当尝试与创建的 table 和原始 SalesTable 建立关系以填充“缺失日期”时，我没有成功。如果有人遇到过类似的问题并有任何建议或可以向我指出解决此问题的资源，我将不胜感激。

我在下面包含了我当前和预期结果的示例。谢谢！

当前：

Item Group	Daily Sales Date	Total
Fruit	January 1	5
Vegetable	January 5	10

预计：

Item Group	Daily Sales Date	Total
Fruit	January 1	5
Fruit	January 2	0
Fruit	January 3	0
Fruit	January 4	0
Fruit	January 5	0
Vegetable	January 1	0
Vegetable	January 2	0
Vegetable	January 3	0
Vegetable	January 4	0
Vegetable	January 5	10

Answer 1

要按照您的要求在 Power Query 中执行此操作，您可以在 Power Query 中创建日期 Table，然后 Join 它与项目组列中的每个组一起创建：

let
    Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("i45WcisqzSxR0lHySswrTSyqVDAEsk2VYnWilcJS01NLEpNyUpFkTYFsQwOl2FgA", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type nullable text) meta [Serialized.Text = true]) in type table [#"Item Group" = _t, #"Daily Sales Date" = _t, Total = _t]),
    #"Changed Type" = Table.TransformColumnTypes(Source,{
        {"Item Group", type text}, 
        {"Daily Sales Date", type date}, 
        {"Total", Int64.Type}}),

//create a table with a list of all dates for the date range in the table
    allDates = Table.FromColumns({
                    List.Dates(List.Min(#"Changed Type"[Daily Sales Date]),
                Duration.Days(List.Max(#"Changed Type"[Daily Sales Date]) - List.Min(#"Changed Type"[Daily Sales Date]))+1,
                #duration(1,0,0,0))},type table[Dates=date]),

//group by the item group column
//Then join each subtable with the allDates table
    group = Table.Group(#"Changed Type",{"Item Group"},{
        {"Daily Sales Date", each Table.Join(_,"Daily Sales Date",allDates,"Dates",JoinKind.RightOuter)}
    }),

//Expand the grouped table
    #"Expanded Daily Sales Date" = Table.ExpandTableColumn(group, "Daily Sales Date", {"Total", "Dates"}, {"Total", "Dates"}),

//replace the nulls with zero's
    #"Replaced Value" = Table.ReplaceValue(#"Expanded Daily Sales Date",null,0,Replacer.ReplaceValue,{"Total"}),

//set proper column order and types
    #"Reordered Columns" = Table.ReorderColumns(#"Replaced Value",{"Item Group", "Dates", "Total"}),
    #"Changed Type1" = Table.TransformColumnTypes(#"Reordered Columns",{{"Dates", type date}, {"Total", Int64.Type}})
in
    #"Changed Type1"

如果您想在现有日期范围内取平均值，您可以试试这个：

let
    Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("i45WcisqzSxR0lHySswrTSyqVDAEsk2VYnWilcJS01NLEpNyUpFkTYFsQwOl2FgA", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type nullable text) meta [Serialized.Text = true]) in type table [#"Item Group" = _t, #"Daily Sales Date" = _t, Total = _t]),
    #"Changed Type" = Table.TransformColumnTypes(Source,{
        {"Item Group", type text}, 
        {"Daily Sales Date", type date}, 
        {"Total", Int64.Type}}),

//count the number of dates
    numDates = Duration.Days(List.Max(#"Changed Type"[Daily Sales Date]) - List.Min(#"Changed Type"[Daily Sales Date]))+1,
    
//group by Item Group, then average using Sum/Number of dates for each subgroup
    #"Grouped Rows" = Table.Group(#"Changed Type", {"Item Group"}, {
        {"Average", each List.Sum([Total])/numDates}})
in
    #"Grouped Rows"

还有许多其他方法可以实现您可能需要的功能。

在 PowerBI 的另一列中为各自的组和默认值添加 "missing" 日期行？

Add "missing" date rows for respective group and default value in another column in PowerBI?

dax

powerquery

powerbi