VBA 创建突出显示的单元格列表

Question

我正在尝试创建工作簿中不同选项卡上突出显示的单元格的合并列表。据我了解 VBA 是我最好的选择。逻辑是这样的：

遍历所有选项卡并如果单元格 = 颜色索引 4 那么复制值并粘贴到名为 'highlightedcells'

的选项卡中

我目前就此

sub findhighlights
For Each ws In ActiveWorkbook.Worksheets
For Each Cell In ws.UsedRange.Cells
If Cell.Interior.ColorIndex = 4 Then
cell.value.copy

欢迎任何帮助。

Answer 1

试试这个：

Sub findhighlights()
    Dim wb As Workbook, ws As Worksheet, c As Range, wsList As Worksheet
    
    Set wb = ActiveWorkbook               'always use a specific workbook
    Set wsList = wb.Worksheets("Listing") 'listing goes here
    For Each ws In wb.Worksheets          'loop sheets
        If ws.Name <> wsList.Name Then    'skip the "Listing" sheet
            For Each c In ws.UsedRange.Cells
                If c.Interior.ColorIndex = 4 Then
                    'list info for this cell
                    With wsList.Cells(Rows.Count, "A").End(xlUp).Offset(1)
                        .Resize(1, 3).Value = Array(ws.Name, c.Address, c.Value)
                    End With
                End If
            Next c
        End If 'is not the Listing sheet
    Next ws
End Sub

VBA 创建突出显示的单元格列表

VBA Creating list of highlighted cells

excel

vba