Windows 只保留目录中 N 个最新文件夹的批处理脚本

Question

我有一个目录，我将 MySQL 数据库备份到当前日期的文件夹中。

现在 30 或 60 天后，我想只保留该备份目录中的 n 个最新文件夹并删除其余文件夹，每个文件夹中都有 gzip 数据库。

为了备份 MySQL 数据库，我使用 adityasatrio's batch script and creating the folder with the current date is also sorted 。

然而，为了这个例子，只保留最新的 3 个文件夹并删除备份目录中的所有其他文件夹似乎很困难。

这是我试过的。

 :: deletes all files and folders in the backupDir
 :: for /f "skip=3 delims=" %%a in ('dir "%backupDir%\" /b /o-d') do echo del "%backupDir%\%%a"


 :: deletes only files in backupDir
 :: for /f "skip=3 delims=" %%a in ('dir "%backupDir%\" /b /a-d') do echo del "%backupDir%\%%a"


 :: deletes all files and folders BUT keeps 3 latest FOLDERS in backupDir
 :: for /f "skip=3 delims=" %%a in ('dir "%backupDir%\" /b') do echo del "%backupDir%\%%a"


 :: deletes all files and folders BUT keeps 3 latest FOLDERS in backupDir
 :: for /f "skip=3 delims=" %%a in (' dir "%backupDir%\" /o-d /b') do echo rd /S /Q "%backupDir%\%%a"

请注意，我不打算删除该 backupDir 中可能存在的任何文件。我在删除 backupDir 中除了最新的 3 个文件夹之外的所有文件夹之后，所以基本上删除了带有 gzipped .sql 文件的旧文件夹。

这些问题对我有所帮助，但不知何故我还是做错了。

delete all but X most recent folders

How do I delete old files from a directory while keeping the most recent ones on Windows（文件不是文件夹）

Batch file to delete files older than N days（同样，文件不是文件夹）

https://serverfault.com/questions/49614/delete-files-older-than-x-days （好的措施，同样是文件而不是文件夹..）

这条评论 delete all but X most recent folders 最接近我正在尝试做的事情，但它也会删除 backupDir 中可能存在的所有文件。

**edit1:**刚刚找到 Delete all folders except 2 lastest folders in Windows，看看是否有任何帮助。

下面popd我的拙作的完整脚本在这里。我希望在您的帮助下解决这个问题或进一步阅读。请注意，我对批处理脚本完全陌生。非常感谢对此的任何帮助。请帮助我删除除那些 N 个最新文件夹之外的所有文件夹。 :)

     @echo off

 set dbUser=root
 set dbPassword=root
 set "backupDir=D:\MySQLDumps"
 set "mysqldump=C:\wamp\bin\mysql\mysql5.6.17\bin\mysqldump.exe"
 set "mysqlDataDir=C:\wamp\bin\mysql\mysql5.6.17\data"
 set "zip=C:\Program Files-Zipz.exe"

rem The four lines below will give you reliable YY DD MM YYYY HH Min Sec MS variables in XP Pro and higher.

for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%" & set "MS=%dt:~15,3%"

 set "dirname=%YYYY%-%MM%-%DD% %HH%-%Min%-%Sec%"

 echo "dirName"="%dirName%"
 :: pause

 :: switch to the "data" folder
 pushd "%mysqlDataDir%"

 :: create backup folder if it doesn't exist
 if not exist "%backupDir%\%dirName%\" mkdir "%backupDir%\%dirName%"

 :: iterate over the folder structure in the "data" folder to get the databases

 for /d %%f in (*) do (
 echo processing folder "%%f"

 "%mysqldump%" --host="localhost" --user=%dbUser% --password=%dbPassword% --single-transaction --add-drop-table --databases %%f > "%backupDir%\%dirName%\%%~nxf.sql"

 "%zip%" a -tgzip "%backupDir%\%dirName%\%%~nxf.sql.gz" "%backupDir%\%dirName%\%%~nxf.sql"

  del "%backupDir%\%dirName%\%%~nxf.sql"

 )
 popd

 :: delete all folders but the latest 3


 :: deletes all files and folders in the backupDir
 :: for /f "skip=3 delims=" %%a in ('dir "%backupDir%\" /b /o-d') do echo del "%backupDir%\%%a"


 :: deletes only files in backupDir
 :: for /f "skip=3 delims=" %%a in ('dir "%backupDir%\" /b /a-d') do echo del "%backupDir%\%%a"


 :: deletes all files and folders BUT keeps 3 latest FOLDERS in backupDir
 :: for /f "skip=3 delims=" %%a in ('dir "%backupDir%\" /b') do echo del "%backupDir%\%%a"


 :: deletes all files and folders BUT keeps 3 latest FOLDERS in backupDir
 :: for /f "skip=3 delims=" %%a in (' dir "%backupDir%\" /o-d /b') do echo rd /S /Q "%backupDir%\%%a"

pause

Answer 1

这两条不同的线路有效。保留 backupDir 中可能存在的所有文件，同时仅删除选定的 N 个最新的 nameDir 文件夹。

这是根据@JosefZ 的评论调整的

for /f "skip=2 delims=" %%a in ('dir "%backupDir%\" /B /O:-N /A:D') do echo rd rd /s /q "%backupDir%\%%a"

这也适用于@Magoo 在这里的回答

for /f "skip=2 delims=" %%a in (' dir "%backupDir%\" /b /ad-h /o-d') do rd /s /q "%backupDir%\%%a"

如果您愿意，可以在此处找到完整的工作批处理脚本。

谢谢大家的帮助！

Windows 只保留目录中 N 个最新文件夹的批处理脚本

Windows Batch Script to only keep the N latest FOLDERS in a directory

windows

directory

batch-file