唯一索引约束在 Phoenix 应用程序中不起作用

Question

在我的 Phoenix 应用程序中，我的用户模型如下：

defmodule MyApp.User do
  use MyApp.Web, :model

  schema "users" do
    field :username, :string, unique: true
    field :email, :string, unique: true
    field :crypted_password, :string
    field :password, :string, virtual: true

    timestamps
  end

  @required_fields ~w(email password username)
  @optional_fields ~w()

  @doc """
  Creates a changeset based on the `model` and `params`.

  If no params are provided, an invalid changeset is returned
  with no validation performed.
  """
  def changeset(model, params \ :empty) do
    model
    |> cast(params, @required_fields, @optional_fields)
    |> unique_constraint(:email)
    |> unique_constraint(:username)
    |> validate_format(:email, ~r/@/)
    |> validate_length(:password, min: 5)
  end
end

我还有以下迁移：

defmodule MyApp.Repo.Migrations.CreateUser do
  use Ecto.Migration

  def change do
    create table(:users) do
      add :email, :string
      add :username, :string
      add :crypted_password, :string

      timestamps
    end

    create unique_index(:users, [:email])
    create unique_index(:users, [:username])
  end
end

我的 registration_controller_ex 如下：

defmodule MyApp.RegistrationController do
  use MyApp.Web, :controller
  alias MyApp.User

  def new(conn, _params) do
    changeset = User.changeset(%User{})
    render conn, changeset: changeset
  end

  def create(conn, %{"user" => user_params}) do
    changeset = User.changeset(%User{}, user_params)

    if changeset.valid? do
      user = MyApp.Registration.create(changeset, MyApp.Repo)
      conn
      |> put_flash(:info, "Your account was created")
      |> redirect(to: "/")
    else
      conn
      |> put_flash(:info, "Unable to create account")
      |> render("new.html", changeset: changeset)
    end
  end
end

所以，尽管如此，我很确定我在 User 中的 username 和 email 字段是唯一索引。我还通过调用 unique_constraint 验证 User.changeset 来确保它们是唯一的。但是，当我在我的界面中创建一个与之前创建的用户具有相同电子邮件和用户名的用户时，变更集得到验证并且用户为 "created"。（它实际上并没有创建，当我查看数据库时没有添加任何东西）

我在我的服务器日志中得到以下信息，但是我的changeset.valid？是真的。

[debug] BEGIN [] OK query=139.3ms queue=8.2ms
[debug] INSERT INTO "users" ("crypted_password", "email", "inserted_at", "updated_at", "username") VALUES (, , , , ) RETURNING "id" ["b$MN1YxFUGLMIJYXseZn0sjuuVs9U1jRdYtRr9D8XQsAqdh.D2sRRXa", "email@gmail.com", {{2015, 9, 30}, {11, 7, 25, 0}}, {{2015, 9, 30}, {11, 7, 25, 0}}, "username"] ERROR query=5.5ms
[debug] ROLLBACK [] OK query=0.4ms

此外，我在 User.changeset 函数中查找的其他内容（例如最小密码长度和其他内容）会报告给用户并且工作正常。只是 :email 和 :username 的唯一索引没有被报告。

Answer 1

unique_constraint 将由数据库检查，因此仅在插入记录时触发。调用 changeset.valid? 不会检查约束，因此在本例中 return 为真。您需要检查 Repo 插入的 return 元组并对其进行操作：

def create(conn, %{"user" => user_params}) do
  changeset = User.changeset(%User{}, user_params)
  case  MyApp.Repo.insert changeset do
    {:ok, changeset} -> 
      conn
      |> put_flash(:info, "Your account was created")
      |> redirect(to: "/")      
    {:error, changeset} ->
      conn
      |> put_flash(:info, "Unable to create account")
      |> render("new.html", changeset: changeset)      
  end
end

现在您的 changeset.errors 已经丰富了，您应该可以使用 changeset.errors[:email]

获取错误

唯一索引约束在 Phoenix 应用程序中不起作用

Unique index constraint not working in Phoenix app

elixir

phoenix-framework