如何使项目在 QML 中的圆圈内拖动？

Question

下面的代码允许在由最小和最大拖动值定义的矩形区域中拖动红色小矩形。

我希望它只持续到半径为 100 的父矩形的边界，这意味着它现在是一个圆。

如何在 QML 中将项目拖动到圆圈内？

Window {
    width: 200; height: 200; visible: true

    Rectangle
    {
        x: 10; y: 10
        width: 200; height: 200
        radius: 100
        color: "blue"

        Rectangle {
            x: 10; y: 10
            width: 20; height: 20
            color: "red"

            MouseArea
            {
                id: dragArea
                anchors.fill: parent

                drag.target: parent
                drag.minimumX : 20
                drag.maximumX : 150

                drag.minimumY : 20
                drag.maximumY : 150
            }
        }
    }
}

Answer 1

有点晚了，但我已经准备好参加测验了。

这是一个不完美的解决方案，有一些缺陷。

import QtQuick 2.5
import QtQuick.Window 2.2

Window {
    width: 400; height: 400; visible: true

    Rectangle
    {
        x: 10; y: 10
        width: 200; height: 200
        radius: 100
        color: "blue"

        Rectangle {
            x: 10; y: 10
            width: 20; height: 20
            color: "red"

            MouseArea
            {
                id: dragArea
                anchors.fill: parent

                drag.target: parent
                drag.minimumX : Math.ceil(100 - Math.sqrt(200 * parent.y - Math.pow(parent.y, 2)))
                drag.maximumX : Math.floor(Math.sqrt(200 * parent.y - Math.pow(parent.y, 2)) + 100)

                drag.minimumY : Math.ceil(100 - Math.sqrt(200 * parent.x - Math.pow(parent.x, 2)))
                drag.maximumY : Math.floor(Math.sqrt(200 * parent.x - Math.pow(parent.x, 2)) + 100)
            }
        }
    }
}

想法是，根据 y 和 x 的当前值计算 x 和 y 的最大值和最小值（因此 max-x 取决于当前 y，而 max-y 取决于在当前-x)

其背后的功能是： (r - y)² + (r - x)² = r²

我没有合并的是可拖动的小矩形的尺寸。所以我只强制左上角留在圆圈范围内。然而，这应该很容易适应。考虑到这一点，假设一个圆，半径减少一半的矩形 width/height，并将其移动一半的矩形 width/height。

另一个缺陷是，如果我达到限制之一（顶部、左侧、右侧、底部），矩形可能会闪烁并且不能顺畅地跟随鼠标。

要解决这个问题，您可以使用一个不可见的对象作为助手，可以在周围自由绘制，然后使用它的位置来计算显示的红色矩形的位置。

也许我稍后也会为此添加一个实现。我很确定，这应该会很顺利。

Answer 2

所以我找了一些时间来提供前面提到的 smoother 解决方案。

import QtQuick 2.5
import QtQuick.Window 2.2

Window {
    id: root
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    property int radius: 100

    Rectangle {
        id: circle
        width: 2 * radius
        height: 2 * radius
        radius: root.radius

        color: 'blue'
    }

    Rectangle {
        id: mark
        width: 20
        height: 20
        x: (dragObj.dragRadius <= root.radius ? dragObj.x : root.radius + ((dragObj.x - root.radius) * (root.radius / dragObj.dragRadius))) - 10
        y: (dragObj.dragRadius <= root.radius ? dragObj.y : root.radius + ((dragObj.y - root.radius) * (root.radius / dragObj.dragRadius))) - 10
        color: 'red'

        MouseArea {
            id: markArea
            anchors.fill: parent
            drag.target: dragObj
            onPressed: {
                dragObj.x = mark.x + 10
                dragObj.y = mark.y + 10
            }
        }
    }

    Item {
        id: dragObj
        readonly property real dragRadius: Math.sqrt(Math.pow(x - root.radius, 2) + Math.pow(y - root.radius, 2))
        x: root.radius
        y: root.radius

        onDragRadiusChanged: console.log(dragRadius)
    }
}

我使用dragObj来避免拖动位置的限制。这跨越了从圆心开始的一个向量。只要dragObj本身包含在圆圈内，我就用它的位置作为标记的位置。
但是一旦它离开圆圈，我会将矢量投影到圆圈上，所以它会保持在限制范围内。

为确保每次拖动都在标记上重新开始，我会将 dragObj 的位置重置为标记的位置，每当再次按下鼠标时（新拖动的前提条件-事件）

玩得开心。

如何使项目在 QML 中的圆圈内拖动？

How to make an item drag inside a circle in QML?

qt

drag-and-drop

qml

qt5