如何在 oracle sql 脚本中创建过程并在脚本中使用它？

Question

我想为我的 oracle DB 创建一个 script，drop tables。如果 table 不存在，脚本不会因为失败而退出，只是打印一条文本：“不存在”。

脚本如下：

BEGIN
    EXECUTE IMMEDIATE 'DROP TABLE mytable';
    DBMS_Output.Put_Line(' table dropped');
EXCEPTION WHEN OTHERS THEN
    IF SQLCODE = -942 THEN
        DBMS_Output.Put_Line(' table not exists');
    ELSE
        DBMS_Output.Put_Line(' Unknown exception while dropping table');
        RAISE;
    END IF;
END;

我想在一个脚本中删除很多 table，我不想将这些行写多次。

有什么方法可以将其写入一个 过程或函数 获取参数（table 的名称），并在其中调用该过程脚本？

可能是这样的：

drop_table_procedure('mytableA');
drop_table_procedure('mytableB');

或者可能是一个过程，它获取一个未定义的大小列表（如 java：String ... table names）：

drop_tables_procedure('mytableA','mytableB');

请给我一些例子。谢谢！

Answer 1

是的，您可以在匿名 PL/SQL 块中声明一个 "temporary" 过程：

DECLARE 

  PROCEDURE drop_if_exists(p_tablename VARCHAR)
  IS
  BEGIN
      EXECUTE IMMEDIATE 'DROP TABLE '||p_tablename;
      DBMS_Output.Put_Line(' table dropped');
  EXCEPTION WHEN OTHERS THEN
      IF SQLCODE = -942 THEN
          DBMS_Output.Put_Line(' table not exists');
      ELSE
          DBMS_Output.Put_Line(' Unknown exception while dropping table');
          RAISE;
      END IF;
  END;

BEGIN
  drop_if_exists('TABLE_1');
  drop_if_exists('TABLE_2');
END;
/

Answer 2

在 execute immediate 中您需要添加数据库对象的名称。这是脚本

create table t1 (col1 int);
create table t2 (col1 int);

create procedure drop_my_table(av_name varchar2)
as
begin
    EXECUTE IMMEDIATE 'DROP TABLE '||av_name;
    DBMS_Output.Put_Line(' table dropped');
EXCEPTION WHEN OTHERS THEN
    IF SQLCODE = -942 THEN
        DBMS_Output.Put_Line(' table not exists');
    ELSE
        DBMS_Output.Put_Line(' Unknown exception while dropping table');
        RAISE;
    END IF;

end drop_my_table;

declare
  type array_t is varray(2) of varchar2(30);
  atbls array_t := array_t('t1', 't2');
begin
  for i in 1..atbls.count loop
       drop_my_table(atbls(i));
   end loop; 
end;

Answer 3

你也可以使用下面的

create or replace PROCEDURE drop_if_exists(p_tablename in VARCHAR)
      IS
    v_var1 number;
    begin 
    select 1 into v_var1 from user_tables where table_name=upper(p_tablename);
    if v_var1=1
    then 
    EXECUTE IMMEDIATE 'DROP TABLE '||p_tablename;
    DBMS_Output.Put_Line(' table dropped');
    else
    DBMS_Output.Put_Line(' table not exist');
    end if;
    exception 
    when others then
     DBMS_Output.Put_Line(' Unknown exception while dropping table');
            RAISE;
    end;

调用程序

    begin 
    drop_if_exists('emp');
    end;
    /

如何在 oracle sql 脚本中创建过程并在脚本中使用它？

How to create a procedure in an oracle sql script and use it inside the script?

sql

oracle

procedure

function

sql-scripts