在 NetLogo 中生成列表的排列

Question

我正在尝试在 NetLogo 中生成一个列表，其中包含几个不同的数字 0 到 n 的唯一列表。比如我有这行代码

set mylists [[0 1 2] [0 2 1] [1 0 2] [1 2 0] [2 0 1] [2 1 0]]

我写的是为了使 0 1 和 2 的所有可能的唯一组合没有任何重复列表中的数字。我希望能够做同样的事情，但 n 更大。是否有一个如何执行此操作的示例，或者任何人都知道我可以查看的某种伪代码算法？谢谢！

Answer 1

如果您不介意递归解决方案，您可以这样做：

to-report permutations [#lst] ;Return all permutations of `lst`
  let n length #lst
  if (n = 0) [report #lst]
  if (n = 1) [report (list #lst)]
  if (n = 2) [report (list #lst reverse #lst)]
  let result []
  let idxs n-values n [?]
  foreach idxs [
    let xi item ? #lst
    foreach (permutations remove-item ? #lst) [
      set result lput (fput xi ?) result
    ]
  ]
  report result
end

编辑：更新语法以响应评论。

to-report permutations [#lst] ;Return all permutations of `lst`
  let n length #lst
  if (n = 0) [report #lst]
  if (n = 1) [report (list #lst)]
  if (n = 2) [report (list #lst reverse #lst)]
  let result []
  let idxs range n
  foreach idxs [? ->
    let xi item ? #lst
    foreach (permutations remove-item ? #lst) [?? ->
      set result lput (fput xi ??) result
    ]
  ]
  report result
end

在 NetLogo 中生成列表的排列

Generating permutations of a list in NetLogo

list

permutation

netlogo