如何回显批处理文件中的特殊字符？

Question

我想将以下查询传递给 sqlplus 命令。

select 'Version ID:   ' || a1.BACKUP_VERSION  || CHR(13) || CHR(10)||'Status:  ' || a1.STORAGE_STATUS ||  CHR(13) || CHR(10)|| 'Distribution ID:  ' || a1.DISTRIBUTION_ID FROM epc1_distrib_version a1;

当我使用脱字符 ^ 符号在屏幕上回显时效果很好。

echo select 'Version ID:   ' ^|^| a1.BACKUP_VERSION  ^|^| CHR(13) ^|^| CHR(10)^|^|'Status:  ' ^|^| a1.STORAGE_STATUS ^|^|  CHR(13) ^|^| CHR(10)^|^| 'Distribution ID:  ' ^|^| a1.DISTRIBUTION_ID FROM epc1_distrib_version a1;

它显示正确的查询字符串。但是当我在我的批处理文件中使用它时它不起作用。这是我正在尝试的代码运行:

@ECHO OFF
echo Connecting to Database...
echo +++++++++++++++++++++++++
(
echo user/pass@instance
echo select 'Version ID:   ' ^|^| a1.BACKUP_VERSION  ^|^| CHR(13) ^|^| CHR(10)^|^|'Status:  ' ^|^| a1.STORAGE_STATUS ^|^|  CHR(13) ^|^| CHR(10)^|^| 'Distribution ID:  ' ^|^| a1.DISTRIBUTION_ID FROM epc1_distrib_version a1;
)| sqlplus -s
echo +++++++++++++++++++++++++

它只显示了这个：

Connecting to Database...
+++++++++++++++++++++++++
user/pass@instance
select 'Version ID:   ' || a1.BACKUP_VERSION  || CHR(13
+++++++++++++++++++++++++

它没有将查询传递给 sqlplus 命令，怎么办？

Answer 1

您需要像 ^) 那样转义右括号。您的 echo 命令位于一对括号 () 之间的代码块内；任何未转义的右括号都被解释为该块的结尾。所以固定代码看起来像：

echo select 'Version ID:   ' ^|^| a1.BACKUP_VERSION  ^|^| CHR^(13^) ^|^| CHR^(10^)^|^|'Status:  ' ^|^| a1.STORAGE_STATUS ^|^|  CHR^(13^) ^|^| CHR^(10^)^|^| 'Distribution ID:  ' ^|^| a1.DISTRIBUTION_ID FROM epc1_distrib_version a1;

我也转义了左括号^(，尽管为了代码的易读性，这不是绝对必要的；所以很清楚哪些括号是功能性的，哪些是装饰性的。

在批处理脚本中，您使用管道 | 将输出传递给 sqlplus 命令；这需要像这样双重转义：

@echo off
echo Connecting to Database...
echo +++++++++++++++++++++++++
(
echo user/pass@instance
echo select 'Version ID:   ' ^^^|^^^| a1.BACKUP_VERSION  ^^^|^^^| CHR^^^(13^^^) ^^^|^^^| CHR^^^(10^^^)^^^|^^^|'Status:  ' ^^^|^^^| a1.STORAGE_STATUS ^^^|^^^|  CHR^^^(13^^^) ^^^|^^^| CHR^^^(10^^^)^^^|^^^| 'Distribution ID:  ' ^^^|^^^| a1.DISTRIBUTION_ID FROM epc1_distrib_version a1;
) | sqlplus -s
echo +++++++++++++++++++++++++

这是因为管道在 | 的每一侧创建了新的命令提示符实例，其中代码部分被执行；因此需要从批处理文件运行来自的主命令提示符实例中隐藏特殊字符，并形成管道进程创建的实例。

另一种选择是将要输出的字符串放在一对双引号""之间（假设字符串本身不包含此类字符）。但是，不能使用像 echo "..." 这样的命令行，因为输出中包含了 ""，这是我们不想要的。

一个技巧是使用 set /P，它旨在提示用户输入环境变量的值。我们这里不需要变量（#）而是提示文字：

set /P "#=select 'Version ID:   ' || a1.BACKUP_VERSION  || CHR(13) || CHR(10)||'Status:  ' || a1.STORAGE_STATUS ||  CHR(13) || CHR(10)|| 'Distribution ID:  ' || a1.DISTRIBUTION_ID FROM epc1_distrib_version a1;"

为了避免这个命令等待用户输入，我们将一个 echo 输入它（只是一个 _ 字符）：

echo _| set /P "#=select 'Version ID:   ' || a1.BACKUP_VERSION  || CHR(13) || CHR(10)||'Status:  ' || a1.STORAGE_STATUS ||  CHR(13) || CHR(10)|| 'Distribution ID:  ' || a1.DISTRIBUTION_ID FROM epc1_distrib_version a1;"

最后，让我们在批处理脚本中使用所有这些：

@echo off
echo Connecting to Database...
echo +++++++++++++++++++++++++
(
echo user/pass@instance
echo _| set /P "#=select 'Version ID:   ' || a1.BACKUP_VERSION  || CHR(13) || CHR(10)||'Status:  ' || a1.STORAGE_STATUS ||  CHR(13) || CHR(10)|| 'Distribution ID:  ' || a1.DISTRIBUTION_ID FROM epc1_distrib_version a1;"
echo/
) | sqlplus -s
echo +++++++++++++++++++++++++

与echo相反，set /P显示的文本不以最后的换行符结束；这就是为什么我插入行 echo/，它输出一个换行符。

Answer 2

您可以使用插入符号，但是当您想要通过管道传输它时，您需要将每个特殊字符转义两次，并且使用引号会使整个过程变得很糟糕。

您可以使用延迟扩展来避免这种情况

set "sql=select 'Version ID:   ' || a1.BACKUP_VERSION  || CHR(13) || CHR(10)||'Status:  ' || a1.STORAGE_STATUS ||  CHR(13) || CHR(10)|| 'Distribution ID:  ' || a1.DISTRIBUTION_ID FROM epc1_distrib_version a1;"

(
  echo user/pass@instance
  cmd /v:on /c "echo ^!sql^!"
) | sqlplus -s

顺便说一句。为了测试你的转义，你可以用 more 替换 sqlplus 看看你真正回显的是什么

如何回显批处理文件中的特殊字符？

How to echo special characters in batch file?

sql

oracle

escaping

batch-file