在 Phoenix Framework 中呈现多对多关系 JSON

Question

我有下一个模型

defmodule App.User do
  use App.Web, :model
  alias App.User

  schema "users" do  
    field :name, :string
    has_many :roles_users, App.RolesUser
    has_many :roles, through: [:roles_users, :role]
    timestamps
  end
end 

defmodule App.Role do
  use App.Web, :model

  schema "roles" do
    has_many :roles_users, App.RolesUser
    has_many :users, through: [:roles_users, :user]
    field :name, :string
    timestamps
  end

end

defmodule App.RolesUser do
  use App.Web, :model

  schema "roles_users" do
    belongs_to :role, App.Role
    belongs_to :user, App.User
    timestamps
  end
end

用于多对多关系。我要显示的控制器是

def index(conn, _params) do
  users = Repo.all(User)
        |> Repo.preload(:roles)

  render(conn, "index.json", users: users)
end

在我看来

def render("index.json", %{users: users}) do
  %{users: render_many(users, App.UserView, "user.json")}
end

def render("show.json", %{user: user}) do
  %{user: render_one(user, App.UserView, "user.json")}
end

def render("user.json", %{user: user}) do
  %{id: user.id,
    name: user.name,
    roles: user.roles
 }

当我发送 GET 请求时我收到了这个错误

unable to encode value: {nil, "roles"}

我知道这可能是因为 user.roles 需要以某种方式格式化才能解码 JSON，但我对此一无所知。我试过

的形式

def render("user.json", %{user: user}) do
  %{id: user.id,
    name: user.name,
    roles: render_many(roles, App.UserView, "roles.json")
 }

但是没有用。

在视图中呈现多对多关系的最佳方式是什么？

Answer 1

使用 render_many/4 是正确的。

如果您希望在同一个模块中定义 "role.json" 渲染函数，您可以这样做：

def render("user.json", %{user: user}) do
  %{
    id: user.id,
    name: user.name,
    roles: render_many(user.roles, __MODULE__, "role.json", as: :role)
  }
end

def render("role.json", %{role: role}) do
  %{
    id: role.id
    ... 
  }
end

注意我们将 as: :role 传递给了 render_many 函数。这是因为分配（%{role: role}）部分是从视图名称中推断出来的。在这种情况下，它是 UserView，因此默认情况下它将是 %{user: user}。

如果您定义了一个 RoleView 模块，那么您只需将 def render("role.json") 函数移动到您的新 RoleView 并调用 render_many 而不使用 as 选项:

...
roles: render_many(user.roles, MyApp.RoleView, "role.json")
...

另一个可能更适合您的选择是在您的模型中派生一个协议：

defmodule App.Role do
  use App.Web, :model
  @derive {Poison.Encoder, only: [:id, :name]}

  schema "roles" do
    has_many :roles_users, App.RolesUser
    has_many :users, through: [:roles_users, :user]
    field :name, :string
    timestamps
  end

我个人觉得这会将您的模型与您的视图相结合，所以我更喜欢使用第一个选项。

在 Phoenix Framework 中呈现多对多关系 JSON

Render many to many relationship JSON in Phoenix Framework

elixir

ecto

phoenix-framework