带有处理和音频输入的 NullPointerException

Question

我正在处理一个处理草图，我从一个音频文件中获取输入，我将其主频率映射到三个动画 "snakes" 的运动。该代码有时可以正常工作，有时则不能（NullPointerException）！我想这与一些细节有关，我 missing/don 不明白，但我感到困惑，因为我的代码不会每次都中断！！如果您能检查一下并找出问题所在，我将不胜感激！这是主要草图：

import beads.*;

// sound variables
AudioContext ac;
Gain g;
PowerSpectrum ps;
Frequency f;
String sourceFile;
SamplePlayer player;
float inputFrequency; 
float mappedFrequency;
float prevFrequency;

// visual variables
ShapeA shA1;
ShapeA shA2;
ShapeA shA3;
boolean shA1pressed, shA2pressed, shA3pressed;

void setup() {
  size(900, 600);
  frameRate(30); // doesn't affect sound
  inputFrequency = 0;
  mappedFrequency = 0;
  prevFrequency = 0;

  // get sound source
  ac = new AudioContext();
  sourceFile = sketchPath("") + "data/rite1.mp3";  
  try {
    player = new SamplePlayer(ac, new Sample(sourceFile));
  }
  catch(Exception e)
  {
    println("Exception while attempting to load sample!");
    e.printStackTrace();
    exit();
  }
  g = new Gain(ac, 2, 0.3);
  g.addInput(player);
  ac.out.addInput(g);

  /* prerequisites for getting main frequency */
  ShortFrameSegmenter sfs = new ShortFrameSegmenter(ac);
  sfs.addInput(ac.out);
  FFT fft = new FFT();
  sfs.addListener(fft);
  ps = new PowerSpectrum(); 
  fft.addListener(ps);
  f = new Frequency(44100.0f);
  ps.addListener(f);
  ac.out.addDependent(sfs); 
  /* end of prerequistes */

  ac.start();

  smooth();
  noStroke();
  //strokeWeight(2); // affecting the size of a point
  shA1 = new ShapeA(3); // random factor affecting angle
  shA2 = new ShapeA(6);
  shA3 = new ShapeA(8);
  shA1pressed = false;
  shA2pressed = false;
  shA3pressed = false;
}

void draw() {
  //background(255);
  fill(255,10);
  rect(0-10,0-10,width+20,height+20);

  text(" Input Frequency: ", -100, -100); // for some reason, needed!!
  inputFrequency = f.getFeatures(); // ** THIS IS THE MAIN FREQUENCY **
  mappedFrequency = map(inputFrequency,20,2000,0,20); // computational power!

  if (shA1pressed) {
    shA1.angle();
    shA1.display(shA1.angle);
  }  
  if (shA2pressed) {
    shA2.angle();
    shA2.display(shA2.angle);
  }
  if (shA3pressed) {
    shA3.angle();
    shA3.display(shA3.angle);
  }

  prevFrequency = inputFrequency;
}

void keyPressed() {
  if (key == '1') {
    if (shA1pressed == false) {
      shA1pressed = true;
    } else {
      shA1pressed = false;
    }
  }
  if (key == '2') {
    if (shA2pressed == false) {
      shA2pressed = true;
    } else {
      shA2pressed = false;
    }
  }
  if (key == '3') {
    if (shA3pressed == false) {
      shA3pressed = true;
    } else {
      shA3pressed = false;
    }
  }
}

这里是 ShapeA class:

class ShapeA {
 float angleCount = 7;
 float stepSize = 3.3; 
 int i = 0;
 float angle = radians(270);
 float r;

 ArrayList<PVector> points = new ArrayList<PVector>();

 ShapeA(float _r) {
   // set position of first point
   points.add(new PVector(random(width), random(height)));
   r = _r;
 }

 float angle() {
   if (prevFrequency <= inputFrequency) {
     angle = angle - radians(mappedFrequency*random(r)); 
   } else {
     angle = angle + radians(mappedFrequency*random(r));
   }
   return angle;
 }

 void display(float _angle) {
   PVector point = points.get(i);
   fill(0);
   ellipse(point.x, point.y, 3, 3);

   // add a new point
  PVector prevPoint = points.get(points.size()-1);
  float x = prevPoint.x + cos(_angle) * stepSize;
  float y = prevPoint.y + sin(_angle) * stepSize;
  points.add(new PVector(x, y));

  // check if shape hits display borders
  float a = (floor(random(-angleCount, angleCount)) + 0.5) * 90.0/angleCount;
  if (y <= 0) {
   angle = a+90;
  } 
  else if (x >= width) {
   angle = a+180;
  }
  else if (y >= height) {
   angle = a-90;
  }
  else if (x <= 0) {
   angle = a;
  }
  i++;
 }

}

当我收到错误消息时，这是一条 NullPointerException 消息，突出显示了这一行（在主草图中）：

inputFrequency = f.getFeatures(); // ** THIS IS THE MAIN FREQUENCY **

此外，我还注意到，通过删除以下行

text(" Input Frequency: ", -100, -100);

我也收到同样类型的信息，虽然线路没用！

谁能解释一下，为什么会发生这些 "things"？

提前致谢， - 伊利亚斯

Answer 1

以后，您应该尝试 post 您遇到的任何错误的全文，以及您正在使用的库的链接。

但我有一个理论：

Frequency class has a function called getFeatures()其中returns一个Float。

注意 Float 中的大写字母 F。它是一个对象，而不是原始的小写 float。 这意味着它可以为空。

然后当你将它转换为小写 float（通过拆箱）时，你会得到一个 NullPointerException 因为它不知道如何将 null 转换为 float.

我不知道为什么那个函数返回 null；您必须检查文档并为此进行一些调试。但是您要么必须追查原因并防止它发生，要么必须添加一个空检查，仅当该值不为空时才输入您的代码。像这样：

Float returnedFrequency = f.getFeatures();
if(returnedFrequency != null){
   inputFrequency = returnedFrequency;
   //rest of your code

至于为什么需要text()这个功能，我猜是巧合吧。我想可能它对 Frequency class 中需要发生的任何事情都造成了足够的延迟，但这个延迟应该只有几毫秒，所以我真的怀疑是这样的。无论如何，如果您追查 null 的原因或添加 null 检查，这将成为一个有争议的问题。

顺便说一下，您在此处 post 编写了一堆额外的代码 - 您的问题与键盘无关，因此所有这些代码只会使您的问题变得混乱。下次，尝试创建一个 MCVE- 我们可以运行得到相同错误的几行，而不是你的整个草图。祝你好运。

带有处理和音频输入的 NullPointerException

NullPointerException with Processing and audio input

audio

processing

nullpointerexception