排序列表并消除 XSLT 中的重复项？

Question

起点是一个 XML-列表，例如

<attributes>
        <para role="tocmain1"/>
        <para role="tocmain1"/>
        <other style="fix"/>
        <other style="fix"/>
        <para role="tocmain2"/>
        <para role="tocmain2"/>
        <para role="tocmain2"/>
        <para role="tocmain3"/>
        <para role="tocmain3"/>
        <para language="de"/>
        <para language="de"/>
        <para role="tocmain3"/>
</attributes>

我想将每个元素 + 属性 + 值实例的出现次数减少到一次。

像这样：

<attributes>
     <other style="fix"/>
     <para language="de"/>
     <para role="tocmain1"/>
     <para role="tocmain2"/>
     <para role="tocmain3"/>    
</attributes>`

到目前为止，我只成功地按字母顺序排列了列表。到目前为止，我所有减少列表的尝试都是徒劳的。

这就是我现在拥有的：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
<xsl:template match="/">
    <attributes>
        <xsl:for-each select="attributes/node()">               
            <xsl:sort select="name()" order="ascending"/>           
            <xsl:sort select="@*" order="ascending"/>                   
            <xsl:choose> 
                <xsl:when test="name() = name(preceding::*[1]) and self::node()/@* = preceding::*/@*"/> 
                <xsl:otherwise>
                    <xsl:copy-of select="."/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each> 
    </attributes>
</xsl:template>
</xsl:stylesheet>

Answer 1

您的 XSLT 生成您请求的 XML 模数一些可以用 xsl:output 和 xsl:strip-space 解决的格式问题。此外，您可以利用 distinct-values() 来简化您的代码：

你的XML输入文档，

<attributes>
  <para role="tocmain1"/>
  <para role="tocmain1"/>
  <para role="tocmain1"/>
  <para role="tocmain1"/>
  <para role="tocmain2"/>
  <para role="tocmain2"/>
  <para role="tocmain2"/>
  <para role="tocmain2"/>
  <para role="tocmain2"/>
  <para role="tocmain3"/>
  <para role="tocmain3"/>
  <para role="tocmain3"/>
</attributes>

给予这个精简的 XSLT，

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="2.0">
  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="/attributes">
    <attributes>
      <xsl:for-each select="distinct-values(para/@role)">
        <xsl:sort select="." order="ascending"/>
        <para role="{.}"/>
      </xsl:for-each> 
    </attributes>
  </xsl:template>
</xsl:stylesheet>

将生成此 XML 输出文档，

<?xml version="1.0" encoding="UTF-8"?>
<attributes>
   <para role="tocmain1"/>
   <para role="tocmain2"/>
   <para role="tocmain3"/>
</attributes>

根据要求。

Answer 2

您还可以对组中的第一个节点使用 xsl:for-each-group 和 xsl:apply-templates。这应该可以轻松添加将来可能需要发生的任何其他转换。

XML 输入（修改以显示正确排序）

<attributes>
    <para role="tocmain3"/>
    <para role="tocmain2"/>
    <para role="tocmain1"/>
    <para role="tocmain3"/>
    <para role="tocmain1"/>
    <para role="tocmain2"/>
    <para role="tocmain1"/>
    <para role="tocmain1"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>
    <para role="tocmain2"/>
    <para role="tocmain2"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>
</attributes>

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/*">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:for-each-group select="*" group-by="@role">
        <xsl:sort select="@role"/>
        <xsl:apply-templates select="current-group()[1]"/>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

XML输出

<attributes>
   <para role="tocmain1"/>
   <para role="tocmain2"/>
   <para role="tocmain3"/>
</attributes>

Answer 3

好的，根据 Daniel Haley 的建议，我找到了适合我的问题的答案。

我现在一个接一个使用两个xsl:

XSL 给出一个没有重复项的无序列表

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>       
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
     </xsl:template>      
     <xsl:template match="/*">
         <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:for-each-group select="*" group-by="@*">
                <xsl:sort select="@*"/>
                <xsl:apply-templates select="current-group()[1]"/>
            </xsl:for-each-group>
        </xsl:copy>
    </xsl:template>       
</xsl:stylesheet>

排序列表的XSL:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="2.0">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="/">
        <attributes>
            <xsl:for-each select="attributes/node()">                 
                <xsl:sort select="name()" order="ascending"/> 
                <xsl:sort select="name(@*)" order="ascending"/>                   
                <xsl:sort select="@*" order="ascending"/>                  
                <xsl:copy-of select="."/>                  
            </xsl:for-each>   
        </attributes>
    </xsl:template>           
</xsl:stylesheet>

请求结果：

<attributes>
    <other style="fix"/>
    <para language="de"/>
    <para role="tocmain1"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>    
</attributes>

感谢您帮我找到答案，对于误导性的示例，我们深表歉意XML！如果有人知道如何将这两个步骤合并到一个脚本中：欢迎您！

排序列表并消除 XSLT 中的重复项？

Sort list and eliminate duplicates in XSLT?

xml

sorting

xslt

duplicates

xslt-2.0