如何将可点击链接添加到自定义 Inno Setup WelcomeLabel？

Question

我有一个带有自定义 WelcomeLabel2 消息的 Inno 安装程序。

[Messages]
WelcomeLabel2=Lorem ipsum dolor sit amet CLICK_HERE consectetur adipiscing elit.

我正在尝试使 CLICK_HERE 成为网站的可点击 link。

我想知道的另一件事是如何将此 CLICK_HERE 文本设为粗体。

我怎样才能做到这一点？

Answer 1

不容易。

要创建一个整体可点击的标签，您可以使用如下代码：

procedure OpenBrowser(Url: string);
var
  ErrorCode: Integer;
begin
  ShellExec('open', Url, '', '', SW_SHOWNORMAL, ewNoWait, ErrorCode);
end;

procedure LinkClick(Sender: TObject);
begin
  OpenBrowser('https://www.example.com/');
end;

procedure InitializeWizard;
var
  Link: TLabel;
begin
  Link := TLabel.Create(WizardForm);
  Link.Left := ???;
  Link.Top := ???;
  Link.Parent := WizardForm.WelcomePage;
  Link.Caption := 'CLICK_HERE';
  Link.OnClick := @LinkClick;
  Link.ParentFont := True;
  Link.Font.Style := Link.Font.Style + [fsUnderline, fsBold];
  Link.Font.Color := clBlue;
  Link.Cursor := crHand;
end;

另见 Show License Agreement link in Inno Setup while installation。

虽然创建一个只有部分文本可点击的标签是一种更困难的方法。如果文本适合一行，可以通过将三个标签彼此相邻堆叠（首先是前导静态文本，然后是 link，然后是尾随静态文本）。但是，如果文本不能放在一行中，那是行不通的，因为标签会相互重叠。

或者，您可以使用 link 创建一个 RTF 文档并使用只读 TRichEditViewer:

显示它

procedure InitializeWizard;
var
  RichViewer: TRichEditViewer;
begin
  RichViewer := TRichEditViewer.Create(WizardForm);
  RichViewer.Left := WizardForm.WelcomeLabel2.Left;
  RichViewer.Top := WizardForm.WelcomeLabel2.Top;
  RichViewer.Width := WizardForm.WelcomeLabel2.Width;
  RichViewer.Height := WizardForm.WelcomeLabel2.Height;
  RichViewer.Parent := WizardForm.WelcomeLabel2.Parent;
  RichViewer.BorderStyle := bsNone;
  RichViewer.TabStop := False;
  RichViewer.ReadOnly := True;
  WizardForm.WelcomeLabel2.Visible := False;
   
  RichViewer.RTFText :=
    '{\rtf1 Lorem ipsum dolor sit amet ' +
    '{\b {\field{\*\fldinst{HYPERLINK "https://www.example.com/" }}' + 
    '{\fldrslt{CLICK_HERE}}}} ' +
    'consectetur adipiscing elit.}';
end;

您需要 Unicode 版本（Inno Setup 6 的唯一版本），请参阅

要更改 link 颜色，请参阅

正如@Bill_Stewart 评论的那样，您应该避免以提升的权限启动浏览器。有关解决方案，请参阅 How to open a web site after uninstallation in non-elevated mode?

如何将可点击链接添加到自定义 Inno Setup WelcomeLabel？

How to add clickable links to custom Inno Setup WelcomeLabel?

inno-setup