如何用 Awk 生成 2 像素的 BMP 图像？

Question

抱歉这个愚蠢的问题，但我正在尝试使用 Awk 创建（生成）一个简单的 BMP 图像 2x1、24 位位图，像素格式为 RGB24。

格式为 "BitmapFileHeader (2+4+4+4=14 bytes) + DIBHeader (4+4+4+2+2+4+4+4+4+4+4=40 bytes) = 54byte"，然后是像素数组（位图数据）的开始。这是我的简单脚本：

BEGIN {
ORS="";
filebmp="Image.bmp"
# BMP Header: 2+4+4+4=14 bytes
printf("%c%c",66,77)>filebmp;
printf("%c%c%c%c",62,0,0,0)>filebmp;
printf("%c%c%c%c",0,0,0,0)>filebmp;
printf("%c%c%c%c",54,0,0,0)>filebpm;

# DIB Header: 4+4+4+2+2+4+4+4+4+4+4=40 bytes
printf("%c%c%c%c",40,0,0,0)>filebmp;
printf("%c%c%c%c",2,0,0,0)>filebmp;
printf("%c%c%c%c",1,0,0,0)>filebmp;
printf("%c%c",1,0)>filebmp;
printf("%c%c",24,0)>filebmp;
printf("%c%c%c%c",0,0,0,0)>filebmp;
printf("%c%c%c%c",8,0,0,0)>filebmp;
printf("%c%c%c%c",19,11,0,0)>filebmp;
printf("%c%c%c%c",19,11,0,0)>filebmp;
printf("%c%c%c%c",0,0,0,0)>filebmp;
printf("%c%c%c%c",0,0,0,0)>filebmp;

# start of pixel array (bitmap data)
# Blu pixel
printf ("%c%c%c",127,0,0)>filebmp;
# Green pixel
printf ("%c%c%c",0,127,0)>filebmp;
# Padding
printf ("%c%c",0,0)>filebmp;
}

有效（下图）：它生成 2x1 和 62 字节大小的 BMP 图像。

http://i60.tinypic.com/mlihyt.jpg

但是，现在，如果在位图数据中我用 128 替换 127 值（例如在蓝色像素中），相同的脚本 Awk 会生成一个 2x1 但 63 字节大小的 BMP 图像 "other colours"（见下图)!

http://i62.tinypic.com/2ltkjlg.png

我想知道我哪里错了...

...有什么想法吗？

谢谢，再见

Answer 1

我能够使用 gawk 重现该问题。似乎 gawk 根据您的 LANG 环境变量选择输出编码。（这里我将 127 的两个实例都更改为 128。）

$ LANG=en_US.LATIN1 gawk -f bit.awk
$ wc -c Image.bmp
  62 Image.bmp

00000000: 424d 3e00 0000 0000 0000 3600 0000 2800  BM>.......6...(.
00000010: 0000 0200 0000 0100 0000 0100 1800 0000  ................
00000020: 0000 0800 0000 130b 0000 130b 0000 0000  ................
00000030: 0000 0000 0000 8000 0000 8000 0000       ..............

$ LANG=en_US.UTF-8 gawk -f bit.awk
$ wc -c Image.bmp
  64 Image.bmp

00000000: 424d 3e00 0000 0000 0000 3600 0000 2800  BM>.......6...(.
00000010: 0000 0200 0000 0100 0000 0100 1800 0000  ................
00000020: 0000 0800 0000 130b 0000 130b 0000 0000  ................
00000030: 0000 0000 0000 c280 0000 00c2 8000 0000  ................

运行 gawk 在单字节编码下你应该没问题。

如何用 Awk 生成 2 像素的 BMP 图像？

How to generate 2 pixel BMP image with Awk?

awk

image

bitmap