如何为 coffeescript 搜索添加时间延迟

Question

当用户搜索姓氏时，响应是跳跃的。

这是正在发生的事情。我的示例是搜索名称 Moon。

因为 Moon 是最具体的，所以它运行是最快的搜索（例如 15.08） http://localhost:3000/contacts/search_contacts?search_term=Moon&order_by=first_name&sort_direction=asc&grade=all&group=allhttp://localhost:3000/contacts/search_contacts?

因为 M 最不具体，所以它运行是最慢的搜索（例如 22.47） search_term=M&order_by=first_name&sort_direction=asc&grade=all&group=all http://localhost:3000/contacts/search_contacts?

Mo & Moo 也运行。

因此，搜索找到了 Moon，但随后被 'Moo'、'Mo' 和 'M' 的搜索结果覆盖（并导致跳转和搜索不正常工作）。

这是代码（使用 coffeescript）。

  class @ContactsSearch

  constructor: ->

    SearchUtils.configCheckBoxSelectAll('contacts-checkbox-select-all', 'contacts-container','contacts-delete-button')

    SearchUtils.configBtnGroup('contacts-btn-group-grade', doSearch)
    SearchUtils.configBtnGroup('contacts-btn-group-order-by', doSearch)
    SearchUtils.configBtnGroup('contact-btn-group', doSearch)
    SearchUtils.configSortDirBtn('contacts-sort-order-toggle', doSearch)

    configDeleteButton()
    configAjaxPaginationLinks()

    search_box = $('#contacts-search-input')
    search_box.data('search-url')
    search_box.bind 'input', (e, data) ->
      doSearch()


  doSearch = ->
    search_box = $('#contacts-search-input')

    btn_group_grade = $('#contacts-btn-group-grade')
    btn_group_order_by = $('#contacts-btn-group-order-by')
    sort_order_toggle = $('#contacts-sort-order-toggle')
    contact_btn_group = $('#contact-btn-group')

    SearchUtils.resetMasterCheckbox('contacts-checkbox-select-all', 'contacts-delete-button')

    ajaxCall(search_box.data('search-url') + "?search_term=" + search_box.val() + "&order_by=" + btn_group_order_by.data('value') + "&sort_direction=" + sort_order_toggle.data('value') + "&grade=" + btn_group_grade.data('value') + "&group=" + contact_btn_group.data('value'))

  ajaxCall = (finalUrl) ->
    search_box = $('#contacts-search-input')
    contacts_table = $('#contacts-container')
    $.ajax
      url: finalUrl
      type: "GET"
      error: (data, status, xhr) ->
        # do nothing
      success: (data, status, xhr) =>
        contacts_table.html(data)
        configAjaxPaginationLinks()
        $('[data-toggle="popover"]').popover()

        SearchUtils.configContainerCheckBoxs('contacts-checkbox-select-all', 'contacts-container','contacts-delete-button')


  configDeleteButton = ->
    $("#contacts-delete-button").click (event) ->
      event.preventDefault()
      bootbox.confirm "Are you sure?", (result) ->
        if result
          deleteSelectedContacts()

  configAjaxPaginationLinks = ->
    $('#contacts-container').find(".pagination a").click (event) ->
      event.preventDefault()
      search_box = $('#contacts-search-input')
      finalUrl = search_box.data('search-url') + "?" + $(this).attr("href").split("?").slice(1)
      ajaxCall(finalUrl)

  deleteSelectedContacts = ->
    url = $("#contacts-delete-button").data('url')

    deleteIDs = $(".contact-search-item:checked").map(->
      $(this).val()
    ).get()

    $.ajax
      url: url
      type: "POST"
      data: JSON.stringify({ ids: deleteIDs }),
      contentType: "application/json; charset=utf-8",
      dataType: "json"
      error: (data, status, xhr) ->
        # do nothing
      success: (data, status, xhr) =>
        doSearch()

document.addEventListener "turbolinks:load", ->
  new ContactsSearch()

我是 coffeescript 的新手，但我认为我需要更改逻辑。具体来说，我想我需要为此添加一个时间延迟：

 search_box.bind 'input', (e, data) ->
      doSearch()

我尝试将 'input' 更改为 'keyup' 以使其在手指离开键盘时进行搜索，但这没有用。不确定语法是否错误或者这是否不是 coffeescript 约定。

或者，我想我需要在 cofeescript 上添加某种时间延迟但不确定语法？

有什么想法吗？
非常感谢。

Answer 1

您的评论是正确的，因为您需要对输入进行去抖动。您只想在用户停止输入片刻后开始搜索。

最好的方法是通过 setTimout。

setTimeout 将在 X 毫秒内调用一个方法。它还 returns 一个id，您可以通过它取消超时。您将需要使用这两个功能：

# We want to wait for the user to stop typing for 1 second
SEARCH_DELAY = 1000

# here we will save the timeout id so we can cancel the search early
#   if the user keeps on typing
searchTimeoutId = null


search_box.bind 'input', ->
  # First clear the old search timeout if it exists
  clearTimeout searchTimeoutId
  # Then set a new timeout to search the text box contents if the user
  #   doesn't continue typing within 1 second
  searchTimeoutId = setTimeout doSearch, SEARCH_DELAY

请询问您是否需要进一步解释。

旁注：

这在本地开发时工作得很好，但有一些现实世界的场景它不会涵盖。

假设用户正在输入 moon landing，在 moon 和 landing 之间有 1 秒的停顿，这意味着将向服务器发送两个单独的搜索。在本地这很好，他们应该以正确的顺序返回。但是中间有一个复杂的网络，不能保证顺序。

我建议您在每次查询时发送一个时间戳。然后你可以检查你是否已经收到并呈现了一个更新的请求，并在不呈现它们的情况下丢弃太慢的旧响应。

如何为 coffeescript 搜索添加时间延迟

how do I add time delay to coffeescript search

javascript

ruby-on-rails

coffeescript

旁注：