使用 AutoHotKey 将屏幕分成 panes/windows

Question

我想使用 AutoHotKey 将桌面屏幕分成 6 个大小相等的 panes/windows 以简化我的代码审查 activity。

我找不到任何脚本将其分成六个相等的部分，但我发现在这里将屏幕分成 2-4 个部分：Link To The Script

Answer 1

SetWinDelay -1

^1:: Area1()
^2:: Area2()
^3:: Area3()
^4:: Area4()
^5:: Area5()
^6:: Area6()

^7::
i := "" ; number of windows
WinGet, id, list,,, Program Manager
Loop, %id%
{   
    this_ID := id%A_Index%
    WinGet, exStyle, exStyle, ahk_id %this_ID%
    If !(exStyle & 0x100)
        continue
    WinGetTitle, title, ahk_id %this_ID%
    If (title = "")
        continue
    i++
    WinActivate, ahk_id %this_ID%
        Area%i%()
}
return

; Top_Left
Area1(){
    WinRestore, A   
    WinMove, A, , 0, 0,(A_ScreenWidth/3),(A_ScreenHeight/2)
}

; Top_Middle
Area2(){
    WinRestore, A   
    WinMove, A, , (A_ScreenWidth/3), 0,(A_ScreenWidth/3),(A_ScreenHeight/2)
}

; Top_Right
Area3(){
    WinRestore, A   
    WinMove, A, , (2*A_ScreenWidth/3), 0,(A_ScreenWidth/3),(A_ScreenHeight/2)
}

; Bottom_Left
Area4(){
    WinRestore, A   
    WinMove, A, , 0, (A_ScreenHeight/2),(A_ScreenWidth/3),(A_ScreenHeight/2)
}

; Bottom_Middle
Area5(){
    WinRestore, A   
    WinMove, A, , (A_ScreenWidth/3), (A_ScreenHeight/2),(A_ScreenWidth/3),(A_ScreenHeight/2)
}

; Bottom_Right
Area6(){
    WinRestore, A   
    WinMove, A, , (2*A_ScreenWidth/3), (A_ScreenHeight/2),(A_ScreenWidth/3),(A_ScreenHeight/2)
}

使用 AutoHotKey 将屏幕分成 panes/windows

Using AutoHotKey for splitting the screen into panes/windows

autohotkey