了解 Haskell 中的 Fix 数据类型

Question

在 this article 关于 Haskell 中的 Free Monads 中，我们得到了一个定义为 Toy 的数据类型：

data Toy b next =
    Output b next
  | Bell next
  | Done

修复定义如下：

data Fix f = Fix (f (Fix f))

允许通过保留通用类型来嵌套 Toy 表达式：

Fix (Output 'A' (Fix Done))              :: Fix (Toy Char)
Fix (Bell (Fix (Output 'A' (Fix Done)))) :: Fix (Toy Char)

我了解固定点如何用于常规函数，但我没有看到这里的类型是如何减少的。编译器按照哪些步骤来评估表达式的类型？

Answer 1

我会用 Fix 做一个更熟悉、更简单的类型，看看你是否能理解。

这是正常递归定义中的列表类型：

data List a = Nil | Cons a (List a)

现在，回想一下我们如何将 fix 用于函数，我们知道我们必须将函数作为参数传递给它自己。事实上，由于 List 是递归的，我们可以像这样写一个更简单的非递归数据类型：

data Cons a recur = Nil | Cons a recur

你能看出这与函数 f a recur = 1 + recur a 有何相似之处吗？与 fix 将 f 作为参数传递给自己的方式相同，Fix 将 Cons 作为参数传递给自己。让我们并排检查 fix 和 Fix 的定义：

fix :: (p -> p) -> p
fix f = f (fix f)

-- Fix :: (* -> *) -> *
newtype Fix f = Fix {nextFix :: f (Fix f)}

如果忽略构造函数名称等的绒毛，您会发现它们本质上是完全相同的定义！

对于 Toy 数据类型的示例，可以像这样递归地定义它：

data Toy a = Output a (Toy a) | Bell (Toy a) | Done

但是，我们可以使用 Fix 将自身传递给自身，用第二种类型参数替换 Toy a 的所有实例：

data ToyStep a recur = OutputS a recur | BellS recur | DoneS

所以，我们可以只使用 Fix (ToyStep a)，这将等同于 Toy a，尽管形式不同。事实上，让我们证明它们是等价的：

toyToStep :: Toy a -> Fix (ToyStep a)
toyToStep (Output a next) = Fix (OutputS a (toyToStep next))
toyToStep (Bell next) = Fix (BellS (toyToStep next))
toyToStep Done = Fix DoneS

stepToToy :: Fix (ToyStep a) -> Toy a
stepToToy (Fix (OutputS a next)) = Output a (stepToToy next)
stepToToy (Fix (BellS next)) = Bell (stepToToy next)
stepToToy (Fix (DoneS)) = DoneS

您可能想知道，"Why do this?" 通常情况下，没有太多理由这样做。但是，定义这些数据类型的简化版本实际上可以让您创建非常有表现力的函数。这是一个例子：

unwrap :: Functor f => (f k -> k) -> Fix f -> k
unwrap f n = f (fmap (unwrap f) n)

这真是一个不可思议的功能！当我第一次看到它时，我很惊讶！这是一个使用我们之前创建的 Cons 数据类型的示例，假设我们创建了一个 Functor 实例：

getLength :: Cons a Int -> Int
getLength Nil = 0
getLength (Cons _ len) = len + 1

length :: Fix (Cons a) -> Int
length = unwrap getLength

这基本上是 fix 免费的，因为我们在我们使用的任何数据类型上使用 Fix！

现在让我们想象一个函数，假设 ToyStep a 是一个仿函数实例，它只是将所有 OutputS 收集到一个列表中，如下所示：

getOutputs :: ToyStep a [a] -> [a]
getOutputs (OutputS a as) = a : as
getOutputs (BellS as) = as
getOutputs DoneS = []

outputs :: Fix (ToyStep a) -> [a]
outputs = unwrap getOutputs

这就是使用 Fix 而不是拥有自己的数据类型的强大之处：通用性。

了解 Haskell 中的 Fix 数据类型

Understanding the Fix datatype in Haskell

monads

haskell

free-monad

fixpoint-combinators