移动键不工作

Question

当我按下箭头键时没有任何反应，但也没有任何错误：这是怎么回事？如果我删除按键测试，它会相应加速...

在这个阶段，我只是尝试使用箭头键以惯性方式在屏幕上移动一个方块。然而，这是我第一次涉足 AS3，所以我可能会以完全错误的方式去做。

如有任何帮助，我们将不胜感激。

Unit.AS:

package  {
    import flash.display.MovieClip;
    import flash.events.*
    import flash.ui.Keyboard

    public class Unit extends MovieClip {

        var velocityX:Number = 1;
        var velocityY:Number = 1;
        var accellerationX:Number = 1;
        var accellerationY:Number = 1;

        public function Unit(){     
            addEventListener("enterFrame", move);

        }

        private function move(e:Event){

            accellerate()
            this.x += velocityX;
            this.y += velocityY;
        }

        private function accellerate(){

            if (Key.isDown(Keyboard.UP)){
                velocityY += accellerationY;
                trace("Accellerating");
            }
            if (Key.isDown(Keyboard.DOWN)){
                velocityY -= accellerationY;
                trace("Accellerating");
            }
            if (Key.isDown(Keyboard.RIGHT)){
                velocityX += accellerationX;
                trace("Accellerating");
            }
            if (Key.isDown(Keyboard.LEFT)){
                velocityX -= accellerationX;
                trace("Accellerating");
            }

        }
    }

}

Key.AS:

package 
{

import flash.display.Stage;
import flash.events.Event;
import flash.events.KeyboardEvent;

public class Key {

    private static var initialized:Boolean = false;
    private static var keysDown:Object = new Object(); 

    public static function initialize(stage:Stage) {
        if (!initialized) {
            stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressed);
            stage.addEventListener(KeyboardEvent.KEY_UP, keyReleased);
            stage.addEventListener(Event.DEACTIVATE, clearKeys);
            initialized = true;
        }
    }


    public static function isDown(keyCode:uint):Boolean 
    {
        return Boolean(keyCode in keysDown);
    }


    private static function keyPressed(event:KeyboardEvent):void {
        keysDown[event.keyCode] = true;
    }


    private static function keyReleased(event:KeyboardEvent):void {
        if (event.keyCode in keysDown) {
            delete keysDown[event.keyCode];
        }
    }


    private static function clearKeys(event:Event):void {

        keysDown = new Object();
    }
}
}

Answer 1

在您的单元构造函数中调用初始化（阶段）静态函数。

Key.initialize(stage);

移动键不工作

Movement Keys not Working

actionscript-3