将文件内容重定向到命令提示符中的变量

Question

我有一个文件 "file.txt"，其中包含 "dir /s /b *.c"

的输出

我想把 file.txt 的全部内容写在一个变量中。

有什么想法吗？

Answer 1

没有。但是你可以一条一条地过一遍。

for /f "delims=" %A in (file.txt) do echo %A

也许说说你想要达到的目标。由于历史原因，C 的知识对你没有帮助。

Answer 2

您可以使用 set /p:

set /p foo=<file.txt

另见 this question。

Answer 3

Batch-Script 是一个非常有限的工具，对多行变量提供原始支持（具有特定的黑客攻击，在这个场景中无法按预期工作，但如果您有兴趣see this).

唯一合理的解决方案是转向一种功能强大的语言，其他语言都不如 Batch-Script。

Answer 4

一般处理此类问题的方式是回复："What do you want this for?"。但是，您的问题很简单，所以这里就是答案。下面的批处理文件不仅将 file.txt 的内容存储在单个变量中，而且稍后还会将变量值作为单独的行进行处理。

编辑：我添加了从变量值中提取单行作为子字符串的方法。

@echo off
setlocal EnableDelayedExpansion

rem Create variables with LF and CR values:
set LF=^
%empty line 1/2, don't remove%
%empty line 2/2, don't remove%
for /F %%a in ('copy /Z "%~F0" NUL') do set CR=%%a

rem Store the contents of file.txt in a single variable,
rem end each line with <CR><LF> bytes
set "variable="
for /F "delims=" %%a in (file.txt) do (
   set "variable=!variable!%%a!CR!!LF!"
)

rem 1- Show the contents of the variable:
echo !variable!

rem 2- Process the contents of the variable line by line
echo/
set i=0
for /F "delims=" %%a in ("!variable!") do (
   set /A i+=1
   echo Line !i!- %%a
)

rem Get the starting position and length of each line inside the variable
set /A i=0, lastStart=0
for /F "delims=:" %%a in (
      '(cmd /V:ON /C set /P "=^!variable^!" ^& echo/^) ^<NUL ^| findstr /O "^^"'
   ) do (
   set /A len[!i!]=%%a-lastStart-2, i+=1
   set /A start[!i!]=%%a, lastStart=%%a
)
set "len[0]="
set "start[%i%]="
set /A lastLine=i-1

rem 3- Extract individual lines from the variable contents as substrings
:getNumber
   echo/
   set "num="
   set /P "num=Enter line number (nothing to end): "
   if not defined num goto end
   if %num% gtr %lastLine% echo Invalid number & goto getNumber
   for /F "tokens=1,2" %%i in ("!start[%num%]! !len[%num%]!") do (
      echo Line %num%- !variable:~%%i,%%j!
   )
goto getNumber
:end

您必须注意，批处理变量最多只能存储 8K 个字符。

将文件内容重定向到命令提示符中的变量

Redirecting contents of a file to a variable in command prompt

windows

cmd

batch-file