程序集引导加载程序不会跳转到内核

Question

我在汇编中做了一个基本的bootloader，但它并没有真正跳转到内核。它只是说 "Booting..."。我敢肯定这只是我犯的一些愚蠢的错误，比如跳到错误的地方。它应该显示类似 "Booting... Loaded!" 的输出。我也试过在加载之前将 es 设置为 0，但即使那样也行不通。这是我的代码：

mov ax, 9ch
mov ss, ax
mov sp, 4096d
mov ax, 7c0h
mov ds, ax
mov es, ax

xor ah, ah
int 13h

clc

mov si, msg2
call print

mov ah, 02h
xor ax, ax
mov es, ax
mov bx, 0x7E00
mov al, 1h
mov ch, 0
mov cl, 2h
mov dh, 0
int 13h

jc error

jmp 0x7E00

mov si, msg3
call print

error:
mov si, msg
call print
hlt

print:
lodsb
cmp al, 0
jz done
mov ah, 0eh
int 10h
jmp print
done:
ret

msg db "An error occured!!", 0
msg2 db "Booting...", 0
msg3 db "Did not jump to kernel correctly!"

times 510-($-$$) db 0
dw 0xAA55

mov si, msgloaded
call printl
jmp $

printl:
lodsb
cmp al, 0
jz donel
mov ah, 0eh
int 10h
jmp print
donel:
ret

msgloaded db "Loaded!", 0

times 0x400-($-$$) db 0

感谢所有帮助。我会相信任何能帮助我的人。谢谢！

Answer 1

对于高级语言，有很多关于程序员打算在结构循环中包含什么、如何选择变量名等的线索，defines/enums；并且很容易编写无需注释的可维护代码。

对于汇编语言，没有精心选择的变量名和变量类型（例如 ax 不会告诉 reader 它是指向字符串的指针还是长颈鹿的高度或... )，指令通常不显示意图（例如 lea 可能用于乘以常数，可能不会用于加载有效地址），控制流要灵活得多（例如 do(condition1) { } while(condition2) 非常好）和 goto（jmp 和条件分支如 jc）被大量使用。

出于这个原因，written/maintainable 汇编语言使用了很多注释。更具体地说，您将使用右侧的评论来描述您的意图。这使您可以通过阅读注释来检查意图是否正确，然后通过将每行上的指令与其注释进行比较来检查意图是否正确实现。它使避免错误变得更加容易，并且更容易找到错误。

这是带有注释的代码的前半部分：

;Memory Layout
;
; 0x009C:0x1000 = 0x000019C0 = stack top
; 0x07C0:0x0000 = 0x00007C00 = load address
; 0x0000:0x7E00 = 0x00007E00 = kernel address

%define STACK_SEGMENT      0x009C
%define STACK_TOP_OFFSET   0x1000
%define LOAD_SEGMENT       0x07C0
%define KERNEL_SEGMENT     0x0000
%define KERNEL_OFFSET      0x7E00

;_______________________________________________

;Entry point
;
;Input
; dl = BIOS boot device number

    mov ax, STACK_SEGMENT
    mov ss, ax
    mov sp, STACK_TOP_OFFSET
    mov ax, LOAD_SEGMENT
    mov ds, ax
    mov es, ax

;Reset disk system
;
;Note: This should be completely unnecessary. We know the BIOS
;      disk services are working correctly and don't need
;      to be reset because the BIOS just used it successfully
;      to load this code into memory.

    xor ah, ah            ;ah = BIOS "reset disk system" function number
    int 13h               ;Call BIOS disk services
    clc                   ;Unnecessary

;Display welcome message

    mov si, msg2
    call print

;Load kernel from disk
; dl = BIOS boot device number

    mov ah, 02h           ;ah = BIOS "read sectors" function number
    xor ax, ax            ;ax = KERNEL_SEGMENT
    mov es, ax
    mov bx, KERNEL_OFFSET ;es:bx = address to load kernel
    mov al, 1h            ;al = number of sectors to read
    mov ch, 0             ;ch = cylinder number for first sector
    mov cl, 2h            ;cl = sector number for first sector
    mov dh, 0             ;dh = head number for first sector
    int 13h               ;Call BIOS disk services

    jc error              ;Handle error if there was one

;Pass control to "kernel"

    jmp KERNEL_SEGMENT:KERNEL_OFFSET

这是使您的错误显而易见的部分：

                          ;ah = BIOS "read sectors" function number
                          ;ax = KERNEL_SEGMENT

本质上，如果您正确地注释了您的代码，您会注意到将 KERNEL_SEGMENT 加载到 ax 会覆盖 BIOS 功能编号（在 [=12= 的最高 8 位中） ]).这导致这段代码调用 BIOS "reset disk system" 函数并且根本不从磁盘加载任何内容。当它跳转到稍后应该加载内核（但没有加载）的位置时，该内存可能仍然充满零，因为它尚未被使用，但充满零的内存被解码为 add 指令CPU，所以 CPU 愉快地执行了 add 指令。

注意：还有另一个（不相关的）错误 - 您打印字符串的代码使用 lodsb，这取决于方向标志；但是您没有执行 cld 指令来设置方向标志，因此根据 BIOS 保留此标志的（未定义）状态，它可能会打印垃圾。

程序集引导加载程序不会跳转到内核

assembly bootloader won't jump to kernel

x86

assembly

operating-system

16-bit

bootloader