String 到 PAnsiChar 转换麻烦

Question

这些是 C DLL 函数示例及其 Delphi 翻译：

C定义：

DLL_EXPORT int AR_dll_function (const char *terminal_no, const char *description);

Delphi定义：

function Ar_Dll_Function(const TerminalNo: PAnsiChar; const Description: PAnsiChar):Integer;

...

function Ar_Dll_Function(const TerminalNo: PAnsiChar; const Description: PAnsiChar):Integer;
var
  MyFunct : function(const TerminalNo: PAnsiChar; const Description: PAnsiChar):Integer;cdecl;
begin
  Result := 0;
  @MyFunct:=GetProcAddress(HInst,'ar_dll_function');
  if Assigned(MyFunct) then
    Result := MyFunct(TerminalNo, Description);
end;

我使用上面的Delphi函数是这样的：

function SP(const s:string): PAnsiChar;
var
  UTF8Str: RawByteString;
begin
  Result := #0;
  SetCodePage(UTF8Str, 0, False);
  UTF8Str := UTF8Encode(s);
  Result := PAnsiChar(AnsiString(UTF8Str));
end;

...

result := Ar_Dll_Function(SP(dTermNo),SP(descr));

问题出在两个 PAnsiChar 参数之间。当我在调试模式下进入 DLL 函数时，我看到第二个 PAnsiChar 通常与第一个参数相同，或者与函数名称相同：

//parameter examples in string :
dtermno:='AT0000058863'; descr:='NAKİT'; 

//parameter examples in PAnsiChar :
TerminalNo:='AT0000058863'; const Description:='AT0000058863'; //or
TerminalNo:='AT0000058863'; const Description:='ar_dll_function';

我该如何解决这个问题？

Answer 1

你遇到的问题是 SP returns 属于 SP 中局部变量的字符串缓冲区的地址。所以当 SP returns 变量被销毁，指针现在无效。

我会这样调用函数：

var
  dTermNo, descr: string;
....
dTermNo := ...;
descr := ...;
retval := Ar_Dll_Function(PAnsiChar(UTF8String(dTermNo)), PAnsiChar(UTF8String(descr)));

或者，您可以将 UTF-8 编码下推到 Ar_Dll_Function 包装器：

function Ar_Dll_Function(const TerminalNo, Description: string): Integer;
var 
  MyFunct: function(TerminalNo, Description: PAnsiChar): Integer; cdecl;
begin
  Result := 0;
  @MyFunct := GetProcAddress(HInst, 'ar_dll_function');
  if Assigned(MyFunct) then
    Result := MyFunct(PAnsiChar(UTF8String(TerminalNo)), 
      PAnsiChar(UTF8String(Description)));
end;

String 到 PAnsiChar 转换麻烦

String to PAnsiChar conversion trouble

delphi

string

pointers

ansi

char