DAX 'AND' 电力双指标操作员错误

Question

我有一个简单的 DAX 公式，我想用它来区分满足特定条件的客户数量。我有一个 table 定义了这些标准，即我在 power bi 上执行此操作的等级，这是我正在使用的度量；

MTierB = 
var y = SUM('Brand Tiers'[TierB]),
var x = SUM('Brand Tiers'[TierA])                                                                           
return CALCULATE(DISTINCTCOUNT('Sales By Customers'[CUSTOMER_StoreCode]), 

KEEPFILTERS(FILTER('Sales By Customers', 'Sales By Customers'[Total Sales in 

MSU] >= y AND <=x )))

我遇到语法错误。 AND 运算符带有红色下划线，我不明白为什么？请帮忙

Answer 1

在 DAX 中，AND 是一个函数，其中 AND(a,b) 表示 "a and b"。 (Reference)

您可以使用 && 作为逻辑连词。即AND(a,b) == a && b

在您的情况下，您的度量的 FILTER 部分需要看起来像这样

FILTER('Sales By Customers',
       'Sales By Customers'[Total Sales in MSU] >= y &&
       'Sales By Customers'[Total Sales in MSU] <= x)

或者像这样

FILTER('Sales By Customers',
       AND('Sales By Customers'[Total Sales in MSU] >= y,
           'Sales By Customers'[Total Sales in MSU] <= x))

Answer 2

凯文，

此外，变量语句之间没有逗号。

MTierB =
VAR y =    SUM ( 'Brand Tiers'[TierB] ) // no comma
VAR x =    SUM ( 'Brand Tiers'[TierA] )
RETURN
    CALCULATE (
        DISTINCTCOUNT ( 'Sales By Customers'[CUSTOMER_StoreCode] ),
        KEEPFILTERS (
            FILTER (
                'Sales By Customers',
                'Sales By Customers'[Total Sales in MSU] >= y
                    && 'Sales By Customers'[Total Sales in MSU] <= x
            )
        )
    )

DAX 'AND' 电力双指标操作员错误

DAX 'AND' Operator error in power bi measure

dax

powerbi