将 libgdx 核心发布到人工制品

Question

我正在尝试发布一个内部 libGDX 框架，以用于我使用 artifactory 开发的所有游戏。我一直在关注 this guide，但是，我卡在了项目本身实际发布的那一刻。我的libGDX项目只有一个核心模块，因为它本身不是游戏，所以我没有制作桌面和android模块。这是我整个项目的构建脚本

buildscript {


    repositories {
        mavenLocal()
        mavenCentral()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        jcenter()
    }
    dependencies {
        classpath "org.jfrog.buildinfo:build-info-extractor-gradle:latest.release"

    }
}

allprojects {
    apply plugin: "eclipse"
    apply plugin: "idea"

    version = '1.0'
    ext {
        appName = "lichengine"
        gdxVersion = '1.9.8'
        roboVMVersion = '2.3.3'
        box2DLightsVersion = '1.4'
        ashleyVersion = '1.7.0'
        aiVersion = '1.8.0'
    }

    repositories {
        mavenLocal()
        mavenCentral()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://oss.sonatype.org/content/repositories/releases/" }
    }
}

project(":core") {
    apply plugin: "java"


    dependencies {
        compile group: 'org.json', name: 'json', version: '20160810'
        compile "com.badlogicgames.gdx:gdx:$gdxVersion"
        compile "com.badlogicgames.gdx:gdx-freetype:$gdxVersion"
        compile "com.badlogicgames.gdx:gdx-controllers:$gdxVersion"

    }
}

tasks.eclipse.doLast {
    delete ".project"
}

这里是核心模块的构建脚本

apply plugin: "java"
apply plugin: 'com.jfrog.artifactory'
apply plugin: 'maven-publish'

sourceCompatibility = 1.7
[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

sourceSets.main.java.srcDirs = [ "src/" ]


eclipse.project {
    name = appName + "-core"
}
def libraryGroupId = 'my.com.lichengine'
def libraryArtifactId = 'lichengine'
def libraryVersion = '1.0'
publishing {
    publications {
        aar(MavenPublication) {
            groupId libraryGroupId
            version libraryVersion
            artifactId libraryArtifactId

            artifact("$buildDir/publications/aar/${artifactId}-release.aar")
        }
    }
}

artifactory {
    contextUrl = 'http://mywebsite.com:8081/artifactory'
    publish {
        repository {
            repoKey = 'libs-release-local'

            username = artifactory_username
            password = artifactory_password
        }
        defaults {
            publications('aar')
            publishArtifacts = true

            properties = ['qa.level': 'basic', 'q.os': 'android', 'dev.team': 'core']
            publishPom = true
        }
    }
}

当我尝试运行根项目或核心项目上的 artifactoryPublish 任务时，出现以下错误：

lichengine\core\build\publications\aar\lichengine-release.aar' does not exist, and need to be published from publication aar

我错过了什么吗？我在网上搜索的所有内容都是专门针对 android 库的，所以没有什么 helps.It 看起来应该生成的 aar 文件不是。

Answer 1

千辛万苦想通了。我没有使用 aar 出版物，而是使用 mavenJava。这是我更新的出版物块：

publications {
        mavenJava(MavenPublication) {
            groupId libraryGroupId
            version libraryVersion
            artifactId libraryArtifactId
            from components.java
        }
    }

我还必须更新默认块

defaults {
            publications ('mavenJava')
            publishArtifacts = true

            properties = ['qa.level': 'basic', 'q.os': 'android', 'dev.team': 'core']
            publishPom = false
        }

希望看到此内容的任何人都可以使用它来帮助他们制作 libGDX 带有人工制品的库！

将 libgdx 核心发布到人工制品

Publishing libgdx core to artifactory

java

artifactory

gradle

libgdx